如何使用其中的变量制作随机数变量？

Question

所以我一直在尝试编写以下代码：

set /a num1=10
set /a num2=%random% %%60 +%num1%
echo %num2%

（这是简化的）

对于此代码，我需要将 +%num1% 作为变量，因为我需要能够更改最小的数字。

出于某种原因，它没有给我一个随机数，而是给了一个完全不相关的数字，这也不是随机的，但每次都是一样的。我的第一个想法是它可能是添加第二个变量而不是制作随机数。但事实并非如此，我不确定如何解决此问题。

我也试过下面的代码：

set /a num1=10
set /a num2=(%random%*60/32768)+%num1%
echo %num2%

这段代码的问题是，即使没有变量，它似乎也永远无法作为随机发生器工作。

感谢任何帮助。

Answer 1

这里有一些例子可以帮助你：

Set "num1=10"
Set /A "num2 = (%RANDOM% %% 60) + num1"
Echo(%num2%

Set "num1=10"
Set /A "num2 = (%RANDOM% * 60 / 32768) + num1"
Echo(%num2%

请注意，我们只提供了您的批处理文件的一小部分，因此如果此代码是带括号的块的一部分，您可能需要启用延迟扩展并使用 !RANDOM! 并可能分别是!num2! 而不是%RANDOM% 和%num2%。

Answer 2

1. 在第一种形式中，您必须考虑模数偏差，如本问题Why do people say there is modulo bias when using a random number generator? 中所述

（注意：接受的答案有一个缺陷，我在对该问题的回答中指出并提供了解决方案。）

1. 在第一种和第二种形式中，它们的写入方式显示的值范围不正确。更多信息可以在这里找到How to use random in BATCH script?

长话短说：

在这两种形式中，如果您希望范围从 10 开始到 60，则需要将其调整为使用 50 的模数，在第一种形式中，您必须在计算中考虑模数偏差，从而导致一些数字更频繁地出现。

第一种形式可以用这种方法固定：

SET "Min=10"
SET "Max=60"
SET /A "Discard= 32768 - ( ( ( 32768 %% (Min-Max) ) + 1 ) %% (Min-Max) )"
:Rand
  SET /A "num2=%random%"
  IF %num2% GTR %Discard% GOTO :Rand
SET /A "num2= num2 %% (Min-Max) + Min"
echo=%num2%

第二种形式可以用这个方法修复：

SET "Min=10"
SET "Max=60"
SET /A "num2= %random% * ( Max - Min + 1 ) / 32768 + Min "
echo=%num2%

完整脚本示例：

@(SETLOCAL
  ECHO OFF
)

CALL :Main

( ENDLOCAL
  EXIT /B
  pause
)

:Main
  SET "Min=10"
  SET "Max=60"
  SET /A "Discard= 32768 - ( ( ( 32768 %% (Min-Max) ) + 1 ) %% (Min-Max) )"
  ECHO=Form1:
  CALL :Form1
  ECHO=Form2:
  CALL :Form2
  pause

GOTO :EOF

:Form1
  SET "num2=%random%"
  IF %num2% GTR %Discard% GOTO :Form1
  SET /A "num2= num2 %% ( Min - Max ) + Min"
  echo=%num2%
GOTO :EOF

:Form2
  SET /A "num2= %random% * ( Max - Min + 1 ) / 32768 + Min "
  echo=%num2%
GOTO :EOF

结果：

C:\WINDOWS\system32>C:\Admin\SE\testrandom.cmd
Form1:
10
Form2:
31
Press any key to continue . . .

C:\WINDOWS\system32>