如何从英国亚马逊拉图像

Question

我正在尝试从 Amazon.co.uk 下载高分辨率图片。我尝试了中给出的代码 [thread][1] 我遇到了一些问题。

@QHarr 的代码适用于给定的 Amazon.in 网站，但当我尝试使用 Amazon.co.uk 时

.querySelector("#landingImage").getAttribute("data-old-hires") 什么都不返回。这是我正在测试的代码。

Public Sub GetInfo()
    Dim Html As HTMLDocument, results()
    Set Html = New HTMLDocument
    
    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", "https://www.amazon.co.uk/dp/product/B01GFJWHZ0", True
        .send
        Html.body.innerHTML = .responseText
        
        With ThisWorkbook.Worksheets("Sheet1")
            .Cells(1, 2) = Html.querySelector("#productTitle").innerText
            .Cells(1, 2).Offset(0, 1) = Html.querySelector("#landingImage").getAttribute("data-old-hires")
        End With
    End With

End Sub

知道我到底做错了什么吗？

Answer 1

我的猜测是响应 html 被破坏了。但是，您可以轻松地从响应字符串中正则表达式输出该位。

请注意，异步参数也设置为 False，以便有时间加载数据。我对您的代码达到您所说的程度感到有些惊讶。它也应该在 HTMLDocument 中没有与该选择器匹配的事实而绊倒。

Public Sub GetInfo()
    'tools > references > Microsoft HTML Object Library
    Dim re As Object, html As MSHTML.HTMLDocument, xhr As Object, s As String

    Set re = CreateObject("VBScript.RegExp")
    Set xhr = CreateObject("MSXML2.XMLHTTP")
    Set html = New MSHTML.HTMLDocument
    re.Pattern = """hiRes"":""(.*?)"""
    
    With xhr
        .Open "GET", "https://www.amazon.co.uk/dp/product/B01GFJWHZ0", False
        .setRequestHeader "User-Agent", "Mozilla/5.0"
        .send
        s = .responseText
        html.body.innerHTML = s
    End With
    With ThisWorkbook.Worksheets("Sheet1")
        .Cells(1, 2) = html.querySelector("#productTitle").innerText
        .Cells(1, 3) = re.Execute(s)(0).SubMatches(0)
    End With
End Sub

---

正则表达式：