如何以管理员身份从 Windows 命令行运行命令？

Question

我有一个小脚本，可以在 Windows 上为我正在管理的 Bazaar 存储库执行构建和安装过程。我正在尝试以提升的管理权限从 in Windows shell (cmd.exe) 运行脚本——就像我右键单击它并选择 以管理员身份运行一样，但不使用任何需要使用图形界面的方法。

Answer 1

按下开始按钮。在搜索框中输入“cmd”，然后按 Ctrl+Shift+Enter

Answer 2

您所要做的就是使用runas 命令以管理员身份运行您的程序（但要注意）。

runas /user:Administrator "cmdName parameters"

就我而言，这是

runas /user:Administrator "cmd.exe /C %CD%\installer.cmd %CD%"

请注意，您必须使用引号，否则 runas 命令会将开关选项吞噬到 cmd。

另请注意，管理 shell (cmd.exe) 在 C:\Windows\System32 文件夹中启动。这不是我想要的，但很容易将当前路径传递给我的安装程序，并使用绝对路径引用它。

警告：启用管理员帐户

以这种方式使用 runas 需要启用管理帐户，这不是 Windows 7 或 Vista 上的默认设置。但是，here 是一个很棒的教程，介绍了如何通过三种不同的方式启用它：

我自己通过打开管理工具、本地安全策略，然后导航到本地策略\安全选项并更改Accounts: Administrative Account Status 策略启用，这不是链接中显示的三种方式。

实现此目的的更简单方法：

C:> net user Administrator /active:yes

Answer 3

批处理/WSH 混合体能够调用 ShellExecute 以显示 UAC 提升对话框...

@if (1==1) @if(1==0) @ELSE
@echo off&SETLOCAL ENABLEEXTENSIONS
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"||(
    cscript //E:JScript //nologo "%~f0"
    @goto :EOF
)
echo.Performing admin tasks...
REM call foo.exe
@goto :EOF
@end @ELSE
ShA=new ActiveXObject("Shell.Application")
ShA.ShellExecute("cmd.exe","/c \""+WScript.ScriptFullName+"\"","","runas",5);
@end

Answer 4

:: ------- Self-elevating.bat --------------------------------------
@whoami /groups | find "S-1-16-12288" > nul && goto :admin
set "ELEVATE_CMDLINE=cd /d "%~dp0" & call "%~f0" %*"
findstr "^:::" "%~sf0">temp.vbs
cscript //nologo temp.vbs & del temp.vbs & exit /b

::: Set objShell = CreateObject("Shell.Application")
::: Set objWshShell = WScript.CreateObject("WScript.Shell")
::: Set objWshProcessEnv = objWshShell.Environment("PROCESS")
::: strCommandLine = Trim(objWshProcessEnv("ELEVATE_CMDLINE"))
::: objShell.ShellExecute "cmd", "/c " & strCommandLine, "", "runas"
:admin -------------------------------------------------------------

@echo off
echo Running as elevated user.
echo Script file : %~f0
echo Arguments   : %*
echo Working dir : %cd%
echo.
:: administrator commands here
:: e.g., run shell as admin
cmd /k

对于一个演示：self-elevating.bat "带空格的路径" arg2 3 4 "another long argument"

这是另一个不需要创建临时文件的版本。

<!-- : --- Self-Elevating Batch Script ---------------------------
@whoami /groups | find "S-1-16-12288" > nul && goto :admin
set "ELEVATE_CMDLINE=cd /d "%~dp0" & call "%~f0" %*"
cscript //nologo "%~f0?.wsf" //job:Elevate & exit /b

-->
<job id="Elevate"><script language="VBScript">
  Set objShell = CreateObject("Shell.Application")
  Set objWshShell = WScript.CreateObject("WScript.Shell")
  Set objWshProcessEnv = objWshShell.Environment("PROCESS")
  strCommandLine = Trim(objWshProcessEnv("ELEVATE_CMDLINE"))
  objShell.ShellExecute "cmd", "/c " & strCommandLine, "", "runas"
</script></job>
:admin -----------------------------------------------------------

@echo off
echo Running as elevated user.
echo Script file : %~f0
echo Arguments   : %*
echo Working dir : %cd%
echo.
:: administrator commands here
:: e.g., run shell as admin
cmd /k

Answer 5

虽然@amr ali's 代码很棒，但我有一个实例，其中我的 bat 文件包含 > < 标志，但出于某种原因它卡住了它们。

我发现了这个。只需将其全部放在您的代码之前，它就可以完美运行。

REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    exit /B
:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

Answer 6

我会设置一个快捷方式，无论是 CMD 还是您要运行的东西，然后将快捷方式的属性设置为需要管理员，然后从批处理文件中运行快捷方式。我还没有测试确认它会尊重属性，但我认为它更优雅，不需要激活管理员帐户。

此外，如果您将其作为计划任务执行（可以通过代码设置），则可以选择在此处提升运行它。

Answer 7

简单的管道技巧，||，在您的批次顶部使用了一些 .vbs。它将退出常规并以管理员身份重新启动。

@AT>NUL||echo set shell=CreateObject("Shell.Application"):shell.ShellExecute "%~dpnx0",,"%CD%", "runas", 1:set shell=nothing>%~n0.vbs&start %~n0.vbs /realtime& timeout 1 /NOBREAK>nul& del /Q %~n0.vbs&cls&exit

它也del /Q temp.vbs 当它完成使用它。

Answer 8

浏览到C:\windows\System32 并右键单击cmd.exe 并以管理员身份运行。在 Windows 7 上为我工作。

如果您尝试以提升的权限运行脚本，您可以对脚本文件执行相同操作，或使用调度程序的运行作为不同的用户选项来运行脚本。

Answer 9

我刚刚在我的桌面上创建了一个快捷方式，目标是这一行：

C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe -command Start-Process -verb RunAs wt

然后固定在任务栏中:)

Answer 10

我个人对任何建议的解决方案都不满意，所以我追踪并了解了微软自己是如何在没有任何确认的情况下以管理员身份运行某些命令的。

这是我最终从 Windows 注册表中找到的：

*RunAs "D:\Path\To\app.exe"
*RunAs "D:\Path\To\app.exe" [YourCommandArgs]