等待由 IContextMenu.InvokeCommand 启动的进程

Question

我有一个TListView，其项目是文件，用户可以通过双击它们来打开它们。

为此，我将文件保存在 windows 临时文件夹中，启动一个线程，用ShellExecuteEx() 打开保存的文件，并让它等待ShellExecuteInfo.hProcess，如下所示：

TNotifyThread = class(TThread)
private
  FFileName: string;
  FFileAge: TDateTime;
public
  constructor Create(const FileName: string; OnClosed: TNotifyEvent); overload;
  procedure Execute; override;

  property FileName: String read FFileName;
  property FileAge: TDateTime read FFileAge;
end;

{...}

constructor TNotifyThread.Create(const FileName: string; OnClosed: TNotifyEvent);
begin
  inherited Create(True);
  if FileExists(FileName) then
    FileAge(FileName, FFileAge);

  FreeOnTerminate := True;
  OnTerminate := OnClosed;
  FFileName := FileName;

  Resume;
end;

procedure TNotifyThread.Execute;
var
  se: SHELLEXECUTEINFO;
  ok: boolean;
begin
  with se do
  begin
    cbSize := SizeOf(SHELLEXECUTEINFO);
    fMask := SEE_MASK_INVOKEIDLIST or SEE_MASK_NOCLOSEPROCESS or SEE_MASK_NOASYNC;
    lpVerb := PChar('open');
    lpFile := PChar(FFileName);
    lpParameters := nil;
    lpDirectory := PChar(ExtractFilePath(ParamStr(0)));
    nShow := SW_SHOW;
  end;

  if ShellExecuteEx(@se) then
  begin
    WaitForSingleObject(se.hProcess, INFINITE);
    if se.hProcess <> 0 then
      CloseHandle(se.hProcess);
  end;
end;

这样，我可以在用户关闭文件后使用TThread.OnTerminate 事件写回对文件所做的任何更改。

我现在在 JclShell.DisplayContextMenu()（使用 IContextMenu）的帮助下显示 Windows 上下文菜单。

我的目标：等待在上下文菜单中选择的执行操作（例如“属性”、“删除”、..）完成（或以任何方式获得通知），这样我就可以检查临时文件的更改以将其写回，或删除TListItem以防删除。

由于CMINVOKECOMMANDINFO 不像SHELLEXECUTEINFO 那样返回进程句柄，所以我无法以同样的方式进行。

将MakeIntResource(commandId-1) 分配给SHELLEXECUTEINFO.lpVerb 导致对ShellExecuteEx() 的调用以EAccessViolation 崩溃。 SHELLEXECUTEINFO 似乎不支持此方法。

我曾尝试从TrackPopupMenu() 获取带有IContextMenu.GetCommandString() 的命令字符串和命令ID，以便稍后将其传递给SHELLEXECUTEINFO.lpVerb，但GetCommandString() 不会为单击的某些项目返回命令。

工作菜单项：

属性、编辑、复制、剪切、打印、7z：添加到存档（动词是“SevenZipCompress”，不会返回 processHandle），KapserskyScan（动词是“KL_scan”，不会返回 processHandle）

不工作：

“打开方式”或“发送至”中的任何内容

这仅仅是IContextMenu 实现的错误吗？

也许这与我使用AnsiStrings 有关？不过，我无法让GCS_VERBW 工作。还有比这更好的方法来可靠地获取CommandString 吗？

function CustomDisplayContextMenuPidlWithoutExecute(const Handle: THandle; 
const Folder: IShellFolder;
  Item: PItemIdList; Pos: TPoint): String;
var
  ContextMenu: IContextMenu;
  ContextMenu2: IContextMenu2;
  Menu: HMENU;
  CallbackWindow: THandle;
  LResult: AnsiString;
  Cmd: Cardinal;
begin
  Result := '';
  if (Item = nil) or (Folder = nil) then
    Exit;
  Folder.GetUIObjectOf(Handle, 1, Item, IID_IContextMenu, nil,
    Pointer(ContextMenu));
  if ContextMenu <> nil then
  begin
    Menu := CreatePopupMenu;
    if Menu <> 0 then
    begin
      if Succeeded(ContextMenu.QueryContextMenu(Menu, 0, 1, $7FFF, CMF_EXPLORE)) then
      begin
        CallbackWindow := 0;
        if Succeeded(ContextMenu.QueryInterface(IContextMenu2, ContextMenu2)) then
        begin
          CallbackWindow := CreateMenuCallbackWnd(ContextMenu2);
        end;
        ClientToScreen(Handle, Pos);
        cmd := Cardinal(TrackPopupMenu(Menu, TPM_LEFTALIGN or TPM_LEFTBUTTON or
          TPM_RIGHTBUTTON or TPM_RETURNCMD, Pos.X, Pos.Y, 0, CallbackWindow, nil));
        if Cmd <> 0 then
        begin
          SetLength(LResult, MAX_PATH);
          cmd := ContextMenu.GetCommandString(Cmd-1, GCS_VERBA, nil, LPSTR(LResult), MAX_PATH);
          Result := String(LResult);
        end;
        if CallbackWindow <> 0 then
          DestroyWindow(CallbackWindow);
      end;
      DestroyMenu(Menu);
    end;
  end;
end;

我在 How to host an IContextMenu 上阅读了 Raymond Chen 的博客，并在 MSDN 上进行了研究（例如 CMINVOKECOMMANDINFO、GetCommandString()、SHELLEXECUTEINFO 和 TrackPopupMenu()），但我可能错过了一些琐碎的事情。

Answer 1

我最终使用TJvChangeNotify 来监控Windows 临时文件夹，同时将监控文件保存在TDictionary<FileName:String, LastWrite: TDateTime> 中。

因此，每当 TJvChangeNotify 触发 OnChangeNotify 事件时，我都可以检查我的哪些监控文件已被删除（通过检查存在）或已更改（通过比较上次写入时间）。

例如ChangeNotifyEvent:

procedure TFileChangeMonitor.ChangeNotifyEvent(Sender: TObject; Dir: string;
  Actions: TJvChangeActions);
var
  LFile: TPair<String, TDateTime>;
  LSearchRec: TSearchRec;
  LFoundErrorCode: Integer;
begin
  for LFile in FMonitoredFiles do
  begin
    LFoundErrorCode := FindFirst(LFile.Key, faAnyFile, LSearchRec);
    try
      if LFoundErrorCode = NOERROR then
      begin
        if LSearchRec.TimeStamp > LFile.Value then
        begin
          // do something with the changed file
          {...}

          // update last write time
          FMonitoredFiles.AddOrSetValue(LFile.Key, LSearchRec.TimeStamp);
        end;
      end // 
      else if (LFoundErrorCode = ERROR_FILE_NOT_FOUND) then
      begin
        // do something with the deleted file
        {...}

        // stop monitoring the deleted file
        FMonitoredFiles.Remove(LFile.Key);
      end;
    finally
      System.SysUtils.FindClose(LSearchRec);
    end;
  end;
end;