vb.net 自身的类构造函数

Question

我有一个包装类来帮助反序列化传入的 json 消息。 目前我就是这样使用的。

Dim oXMessage As XMessage = JsonConvert.DeserializeObject(Of XMessage)(message)

我想为该类创建一个构造函数，以便更清晰地实例化它。像这样

Dim oXMessage as XMessage = New XMessage(message)        

我尝试了下面的构造函数，但它不起作用。 有人能指出我正确的方向吗？

Public Class XMessage
    <JsonProperty("e")> Public MessageType As String
    <JsonProperty("data")> Public MessageData As Object
    <JsonProperty("ok")> Public MessageOk As String

    Public Sub New(message As String)
        Me = JsonConvert.DeserializeObject(Of Me)(message)
    End Sub
End Class

Answer 1

您不能在构造函数中重新分配Me 的值，因为那是当前正在构造的对象。但是你可以调用JsonConvert.PopulateObject()来初始化它的内容：

Public Class XMessage
    <JsonProperty("e")> Public MessageType As String
    <JsonProperty("data")> Public MessageData As Object
    <JsonProperty("ok")> Public MessageOk As String

    Public Sub New(message As String)
        JsonConvert.PopulateObject(message, Me)
    End Sub

    Public Sub New()
    End Sub
End Class

示例fiddle。

Answer 2

Me关键字指的是当前实例，不能作为赋值的目标。

相反，您可能想要做的是创建一个新对象，对其进行反序列化，然后将新对象的成员变量复制到当前实例。

编辑：没有辅助函数

Public Class XMessage

    <JsonProperty("e")> Public MessageType As String
    <JsonProperty("data")> Public MessageData As Object
    <JsonProperty("ok")> Public MessageOk As String

    Public Sub New(message As String)
        Dim other = JsonConvert.DeserializeObject(Of XMessage)(message)
        Me.MessageType = other.MessageType
        Me.MessageData = other.MessageData
        Me.MessageOk = other.MessageOk
    End Sub

End Class

原文：

Public Class XMessage

    <JsonProperty("e")> Public MessageType As String
    <JsonProperty("data")> Public MessageData As Object
    <JsonProperty("ok")> Public MessageOk As String


    Public Sub New(message As String)
        Dim other as XMessage= Deserialize(message)
        Me.MessageType = other.MessageType
        Me.MessageData = other.MessageData
        Me.MessageOk = other.MessageOk
    End Sub


    Public shared Function Deserialize(message as String) as XMessage
        return JsonConvert.DeserializeObject(Of XMessage)(message)
    End Function

    Public Shared Function Serialize(message As XMessage) As String 
        return JsonConvert.SerializeObject(message)
    End Function

End Class