如何在 VB.NET 中使用泛型？

Question

我有以下代码：

Public Shared Function GetListAsString(ByVal data As List(Of String)) As String
    Dim retVal As String = "| "
    For Each obj As String In data
        retVal = retVal + obj.ToString() + " |"
    Next
    Return retVal
End Function

它将列表转换为可打印的字符串。现在它已设置为与 just 列表一起使用。我觉得它应该能够与任何类型的 Collection 一起工作。我是集合和泛型的新手。当我尝试做类似的事情时

Public Shared Function GetListAsString(ByVal data As Collection(T)) As String
    Dim retVal As String = "| "
    For Each obj As String In data.ToString()
        retVal = retVal + obj.ToString() + " |"
    Next
    Return retVal
End Function

我得到一个错误。谁能指出我正确的方向？

Answer 1

您没有从编译器获得非常有用的错误消息。你忘记了使函数通用，它不能产生一个像样的诊断。让我们关注更大的问题：

    For Each obj As String In data.ToString()
        retVal = retVal + obj.ToString() + " |"
    Next

For 循环被破坏，从 data.ToString() 开始。只用数据。并且数据的元素类型是T，而不是String。此外，由于您只是枚举集合，您可以使用较小的接口 IEnumerable，使其适用于更多集合类型。因此：

Public Shared Function GetCollectionAsString(Of T)(ByVal data As IEnumerable(Of T)) As String
    Dim retVal As String = "| "
    For Each obj As T In data
        retVal = retVal + obj.ToString() + " |"
    Next
    Return retVal
End Function

注意函数名称后添加的(Of T)，它可以解决您原来的错误消息。

Answer 2

Collection(T) 应该是IEnumerable(Of T)？

更新顺便说一句，顺便说一句，只要你想从你的集合对象中得到ToString，并且ToString在Object类中定义并且所有其他类都继承Object，你可以用

Public Shared Function GetListAsString(ByVal data As IEnumerable(Of Object)) As String

Answer 3

您需要在方法签名上指定泛型。

Public Shared Function GetListAsString(Of T)(ByVal data As ICollection(Of T)) As String

编辑我改了。

Answer 4

得益于 VB.Net 推理的魔力，解决方案相同，但代码更少：

Public Shared Function GetListAsString(Of T)(ByVal data As IEnumerable(Of T)) As String
    Dim retVal = "| "    
    For Each obj In data
        retVal &= obj.ToString + " |"
    Next
    Return retVal
End Function

编辑

或者使用 String.Join 甚至更简单...

Public Shared Function GetListAsString(Of T)(ByVal data As IEnumerable(Of T)) As String
    Return "| " & String.Join(" |", data) & " |"
End Function

Answer 5

Hans's answer 的缩短版，使用扩展方法代替显式 For Each 循环：

Public Function GetListAsString(Of T)(ByVal data As IEnumerable(Of T)) As String
    Return data.Aggregate("| ", Function(d, s) d & s.ToString & " |")
End Function

但是你有没有尝试过来自 cmets 的 Snowbear 的建议？

"| " & String.Join(" | ", data) & " |"

这个String.Join 代码的行为确实与您问题中的代码略有不同，但它是如此简单。以下是区别

empty-sequence -> "| |" rather than "| "
1, 2 -> "| 1 | 2 |" rather than "| 1| 2 |" (was that really what you meant?)