在异步工作流中捕获 HttpClient 超时

Question

我通过Async.AwaitTask 呼叫HttpClient，是从代理（邮箱处理器）内部调用的。我想在 HTTP 调用期间捕获错误，因此在异步工作流程中使用了 try...with，但它完全错过了捕获客户端超时异常，然后导致代理崩溃。

最小复制：

#r "System.Net.Http"
open System
open System.Net.Http

let client = new HttpClient()
client.Timeout <- TimeSpan.FromSeconds(1.)
async {
    try
        let! content = Async.AwaitTask <| client.GetStringAsync("http://fake-response.appspot.com/?sleep=30")
        return content
    with ex ->
        // Does not catch client-side timeout exception
        return "Caught it!"
}
|> Async.RunSynchronously
// Throws System.OperationCanceledException: The operation was canceled

我可以通过使其完全同步来修复它，但更愿意保持整个堆栈异步，因为可能会并行运行其中的很多：

#r "System.Net.Http"
open System
open System.Net.Http

let client = new HttpClient()
client.Timeout <- TimeSpan.FromSeconds(1.)
try
    Async.AwaitTask <| client.GetStringAsync("http://fake-response.appspot.com/?sleep=30")
    |> Async.RunSynchronously
with ex ->
    "Caught it!"
// Returns "Caught it!"

是否有在异步上下文中捕获OperationCanceledException 的有效方法？

Answer 1

发生这种情况是因为HttpClient.GetStringAsync 任务将被取消，而不是因为TimeoutException 而失败，因此会提示异步机制触发其无法处理的取消继续。解决这个问题的简单方法如下：

async {
    try
        let! content = 
            client.GetStringAsync("http://fake-response.appspot.com/?sleep=30")
                  .ContinueWith(fun (t:Task<string>) -> t.Result)
            |> Async.AwaitTask
        return content
    with ex ->
        // Does not catch client-side timeout exception
        return "Caught it!"
}