F# 接口和属性

Question

我正在尝试掌握 F#，并且在此过程中我正在转换一些 C# 代码。我在定义接口中的属性并在类型中实现它们时遇到了一些麻烦。

考虑以下代码：

module File1

type IMyInterface =
    abstract member MyProp : bool with get, set
    abstract member MyMethod : unit -> unit

type MyType() = 
    interface IMyInterface with
        member val MyProp = true with get, set
        member self.MyMethod() = if MyProp then () else ()

The documentation for F# properties 似乎表明我在 MyType 中的 MyProp 实现是正确的，但是，编译器抱怨“未定义值或构造函数 'MyProp'”。有什么想法吗？

Answer 1

要访问（显式）接口中的属性，您需要强制转换为对接口类型的self 引用：

type MyType() = 
    interface IMyInterface with
        member val MyProp = true with get, set
        member self.MyMethod() = if (self :> IMyInterface).MyProp then () else ()

如果显式实现接口，在 C# 中也会出现相同的错误，并且还需要强制转换才能访问成员：

interface IMyInterface
{
    bool MyProp { get; set; }
    void MyMethod();
}

class MyType : IMyInterface
{
    bool IMyInterface.MyProp { get; set; }

    void IMyInterface.MyMethod()
    {
        if (((IMyInterface)this).MyProp) { }
    }
}

Answer 2

如果你只是访问接口，那么你不需要在类型本身中定义成员。 如果您想要极简主义，菲尔的回答很好，但另一种方法 我喜欢使用“let-bound”值而不是成员——对于更复杂的代码，类型推断更好 他们通常比成员更容易处理。

type MyType() = 
    let mutable myProp = true 
    let myMethod() = if myProp then () else ()

    interface IMyInterface with
        member __.MyProp with get() = myProp and set v = myProp <- v
        member __.MyMethod() = myMethod()

代码也比会员版本略干净，imo，因为type MyType() as self 中的self 标记 只需要访问 members -- let-bound 值可以直接从接口访问。

Answer 3

这是一个工作版本：

type IMyInterface =
    abstract member MyProp : bool with get, set
    abstract member MyMethod : unit -> unit

type MyType() = 
    member val MyProp = true with get, set
    member self.MyMethod() = if self.MyProp then () else ()
    interface IMyInterface with
        member self.MyProp with get () = self.MyProp and set v = self.MyProp <- v
        member self.MyMethod() = self.MyMethod()

请注意，我包含了明确的成员，因为您肯定会错过它们；）