在带有子项目的项目中设置 CMAKE_CONFIGURATION_TYPES 的位置

Question

假设我有一个包含两个独立子项目的项目。如果我对 cmake 的理解正确，想法是让一个根 CMakeLists.txt 定义一个 project(...)，然后使用 add_subdirectory(...) 包含子项目。每个子项目都有自己的CMakeLists.txt 定义自己的项目。这种方式可以一起构建项目（使用根 cmake 文件）或单独构建（使用子项目 cmake 文件）。

我现在想更改CMAKE_CONFIGURATION_TYPES。我应该在根 CMakeLists.txt 还是在每个子项目中执行此操作，还是两者都执行？

在根目录中更改它意味着单独构建子项目会提供错误的配置类型；其他选项将复制 cmake 代码。我想我在这里遗漏了一些东西。

Answer 1

分解设置依赖于配置的设置的代码。使用以下内容创建一个文件，例如 SetUpConfigurations.cmake：

if(NOT SET_UP_CONFIGURATIONS_DONE)
    set(SET_UP_CONFIGURATIONS_DONE TRUE)

    # No reason to set CMAKE_CONFIGURATION_TYPES if it's not a multiconfig generator
    # Also no reason mess with CMAKE_BUILD_TYPE if it's a multiconfig generator.
    get_property(isMultiConfig GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
    if(isMultiConfig)
        set(CMAKE_CONFIGURATION_TYPES "Debug;Release;Profile" CACHE STRING "" FORCE) 
    else()
        if(NOT CMAKE_BUILD_TYPE)
            message("Defaulting to release build.")
            set(CMAKE_BUILD_TYPE Release CACHE STRING "" FORCE)
        endif()
        set_property(CACHE CMAKE_BUILD_TYPE PROPERTY HELPSTRING "Choose the type of build")
        # set the valid options for cmake-gui drop-down list
        set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug;Release;Profile")
    endif()
    # now set up the Profile configuration
    set(CMAKE_C_FLAGS_PROFILE "...")
    set(CMAKE_CXX_FLAGS_PROFILE "...")
    set(CMAKE_EXE_LINKER_FLAGS_PROFILE "...")
endif()

然后include(..)这个文件在CMakeLists.txt的开头。

关于将SetUpConfigurations.cmake 放在哪里，您有两种选择，这取决于您如何组织项目、存储库：

1. 快速的'n'dirty 方法：复制并提交此脚本到每个需要它的项目中。它的位置将是固定的，相对于项目的CMakeLists.txt。所以你可以包含它，例如，include(${CMAKE_CURRENT_SOURCE_DIR}/<...>/SetUpConfigurations.cmake)

2. 规范的方式：使用您的自定义 CMake 脚本维护一个存储库，例如这个。每次使用cmake 命令生成项目时，都会在CMAKE_MODULE_PATH 变量中传递此存储库的路径：

   cmake -DCMAKE_MODULE_PATH=<dir-of-cmake-script-repo> ...
   

在这种情况下，包括带有include(SetUpConfigurations) 的脚本（没有.cmake 扩展名）。

关于什么是多配置生成器的说明：

Xcode 和 Visual Studio 是多配置生成器。他们尊重CMAKE_CONFIGURATION_TYPES 的值，但CMAKE_BUILD_TYPE 没有任何效果，因为在处理CMakeLists.txt 时没有定义具体配置。稍后将在 IDE 的用户界面上选择它。

另一方面，makefile 风格的生成器对CMAKE_CONFIGURATION_TYPES 不感兴趣。 CMAKE_BUILD_TYPE 定义配置。当CMakeLists.txt文件被处理但仍然是一个具体的值：永远不要根据CMAKE_BUILD_TYPE的值做任何决定：

if(CMAKE_BUILD_TYPE STREQUAL "Release") # WRONG!
    ....
endif()

您的项目无法在多配置生成器中按预期工作。

Answer 2

在子项目目录中使用add_subdirectory 时，您会将几乎所有变量传播到该子项目中，这与“子项目独立性”相矛盾。

相反，最好在execute_process() 中使用嵌套的cmake 调用来构建和安装子项目。如果您想让某些子项目的定义可用于顶级项目，则需要在安装子项目时“导出”这些定义。 This question/answer 帖子描述了如何做到这一点。