XSLT 交换元素值答案

【问题标题】：XSLT swap element valuesXSLT 交换元素值
【发布时间】：2012-07-01 12:54:28
【问题描述】：

我正在尝试使用 xslt 交换 GPX 文件 (XML) 中元素 name 和 cmt 的值。

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<gpx xmlns="http://www.topografix.com/GPX/1/1" creator="GPS TrackMaker" version="1.1" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.topografix.com/GPX/1/1 http://www.topografix.com/GPX/1/1/gpx.xsd">
    <metadata>
        <link href="http://www.trackmaker.com">
            <text>Geo Studio Tecnology Ltd</text>
        </link>
        <time>2012-06-29T21:53:25Z</time>
        <bounds minlat="37.772562" minlon="-124.550080" maxlat="49.323978" maxlon="-122.404474"/>
    </metadata>
    <wpt lat="46.189580000" lon="-123.824460000">
        <ele>0.000000</ele>
        <name>G02010</name>
        <cmt>Columbia River Maritime Museum</cmt>
        <desc>Columbia River Maritime Museum</desc>
        <sym>Museum</sym>
    </wpt>
    <wpt lat="46.189010000" lon="-123.824370000">
        <ele>0.000000</ele>
        <name>G02020</name>
        <cmt>Marine Dr/17th St</cmt>
        <desc>Marine Dr/17th St</desc>
        <sym>Waypoint</sym>
    </wpt>
</gpx>

改造后：

...
<name>Columbia River Maritime Museum</name>
<cmt>G02010</cmt>
...

有人可以为此显示正确的 xslt 吗？谢谢。

【问题讨论】：

标签： xml xslt gpx

【解决方案1】：

使用标识转换并覆盖这些元素的值：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:gpx="http://www.topografix.com/GPX/1/1">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="gpx:name/text()">
        <xsl:value-of select="../../gpx:cmt/text()"/>
    </xsl:template>
    <xsl:template match="gpx:cmt/text()">
        <xsl:value-of select="../../gpx:name/text()"/>
    </xsl:template>
</xsl:stylesheet>

请注意，如果您的实际需求（或源输入）更复杂，您也可以直接匹配元素（而不是它们的 text()）。

看起来像这样：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:gpx="http://www.topografix.com/GPX/1/1">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="gpx:name">
        <xsl:copy>
            <xsl:apply-templates select="@*|../gpx:cmt/text()"/>
        </xsl:copy>
    </xsl:template>
        <xsl:template match="gpx:cmt">
        <xsl:copy>
            <xsl:apply-templates select="@*|../gpx:name/text()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

这是一个稍微更通用的解决方案，但考虑到您提供的输入，第一个就足够了。

【讨论】：