列值更改时触发 SQL 触发器

Question

当“工作状态”为“完成”时，我将日期添加到 SQL 的列中，但我的问题是，当我在软件中再次打开并保存相同的作业时，它会运行触发器并再次更改日期到一个我不想要的新值。

我希望触发器仅在“工作状态”值不是“已完成”时运行。

    GO
/****** Object:  Trigger [dbo].[TRJCD_JOBREQUEST]    Script Date: 06/25/2021 15:49:04 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER            TRIGGER [dbo].[TRJCD_JOBREQUEST] ON [dbo].[TBL_JOBREQUEST] 
AFTER UPDATE,INSERT

AS

if (Update (workstatus))

begin

DECLARE @Jobcompletiondate datetime 
DECLARE @workstatus VARCHAR(15)
DECLARE @jobid int


select @workstatus = workstatus from inserted
select @jobid = jobid from inserted
select @Jobcompletiondate = GETDATE() 

begin

if @workstatus='Completed'


    update TBL_JOBREQUEST set JobCompDate=@Jobcompletiondate where jobid = @jobid 
end
end

Answer 1

以下是构建触发器的方法。

无需为变量分配任何值，触发器每批次触发一次，并且始终在更新的行的集合上操作。

如果您将状态更新为已完成，您需要检查它当前是否已完成，此外，如果您想保留第一个 JobCompDate，即使状态随后被修改，只需使用 case 表达式仅更新当前所在的列空。

create or alter trigger [dbo].[TRJCD_JOBREQUEST] on [dbo].[TBL_JOBREQUEST] 
after update,insert
as
if @@RowCount=0 return

set nocount on
if Update (workstatus)
begin

    update t set
        t.JobCompDate=case when t.JobCompDate is null then GetDate() else t.JobCompDate end
    from inserted i join TBL_JOBREQUEST t on t.jobid=i.jobid
    where i.workstatus='Completed' 
    and not exists (
      select * from deleted d 
      where d.jobid=i.jobid and d.workstatus=i.workstatus
    )

end

Answer 2

请注意，我没有您的数据集，因此无法测试触发器，但是，根据您在问题中提供的内容，我相信这就是您正在寻找的答案：

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER            TRIGGER [dbo].[TRJCD_JOBREQUEST] ON [dbo].[TBL_JOBREQUEST] 
AFTER UPDATE,INSERT

AS

if (Update (workstatus))

begin

DECLARE @Jobcompletiondate datetime 
DECLARE @currentworkstatus VARCHAR(15)
DECLARE @oldworkstatus VARCHAR(15)
DECLARE @jobid int


select @oldworkstatus = workstatus from deleted
select @currentworkstatus = workstatus from inserted
select @jobid = jobid from inserted
select @Jobcompletiondate = GETDATE() 

begin

if @currentworkstatus='Completed' and @oldworkstatus <> 'Completed'


    update TBL_JOBREQUEST set JobCompDate=@Jobcompletiondate where jobid = @jobid 
end
end

您需要检查删除的workstatus 是否不等于Completed，然后才应该触发触发器。