在 Perl 中使用裸词有哪些陷阱？

Question

我知道在引用运算符（q//、qq//）、哈希键等中可以将裸词用作字符串。我个人对此不太感兴趣，因为我无法克服心理预期应该引用文字字符串，如在 C、C++ 中。但是，如果我要混合使用带引号的字符串和裸词，我想确保我不会意外地在裸词在运行时无法正常运行的情况下误伤自己。

请排除“use strict”会在编译时将其捕获为错误的用例。我总是启用“严格”模式，所以我不关心这些情况。

下面是根据提供的答案和cmets的代码说明：

#!/usr/bin/perl

use strict;

use constant SIZE => "const_size";

sub size {
    return "getsize";
}

my $href = {
    size => 1,
    getsize => 2,
    const_size => "CONST_SIZE",
    SIZE => "LARGE",
};

print "constant SIZE:", SIZE, "\n";
print "1. \$href->{size}:", $href->{size}, "\n";
print "1a. \$href->{size()}:", $href->{size()}, "\n";
print "2. \$href->{getsize}:", $href->{getsize}, "\n";
print "3. \$href->{SIZE}:", $href->{SIZE}, "\n";
print "3a. \$href->{(SIZE)}:", $href->{(SIZE)}, "\n";

输出：

$ ./bare_word.pl
constant SIZE:const_size
1. $href->{size}:1
1a. $href->{size()}:2
2. $href->{getsize}:2
3. $href->{SIZE}:LARGE
3a. $href->{(SIZE)}:CONST_SIZE

似乎对于散列键，裸词在所有情况下的行为都符合预期。要覆盖该行为，我们需要明确消除歧义。

Answer 1

请排除“use strict”会在编译时将其捕获为错误的用例。

use strict; 完全禁止使用barewords。允许使用裸词可以让拼写错误非常安静和/或巧妙地失败。

文档声称小写裸字可能会被误解为 Perl 未来版本中的函数调用，但事实并非如此。需要启用新功能，例如say。

---

也就是说，我认为您实际上是在谈论自动引用的哈希键。可能会造成混淆，因为人们可能会写$hash{foo}，期望它等同于$hash{foo()}。但不仅foo（相对于foo()）是一种奇怪的调用sub 的方式，而且没有人会想首先写$hash{foo()}。 （肯定需要论证。）

唯一能防止代码被误解的可能性非常小，那就是常量被用作哈希键的可能性。 $hash{CONSTANT} 会失败。需要使用$hash{(CONSTANT)}、$hash{+CONSTANT} 或其他某种形式的消歧。

Answer 2

是的，如果没有正确引用的话，你可能会自取其辱：

$ perl -MData::Dumper -e'
    my %h;
    $h{"foo-bar"} = 1;
    print Dumper \%h
'
$VAR1 = {
          'foo-bar' => 1
        };

$ perl -MData::Dumper -e'
    my %h;
    $h{foo-bar} = 1;
    print Dumper \%h
'
$VAR1 = {
          '0' => 1  # oops!
        };

但是，严格模式会将其从未捕获的逻辑错误转变为语法错误：

$ perl -Mstrict -MData::Dumper -e'
    my %h; 
    $h{foo-bar} = 1; 
    print Dumper \%h
'
Bareword "foo" not allowed while "strict subs" in use at -e line 1.
Bareword "bar" not allowed while "strict subs" in use at -e line 1.
Execution of -e aborted due to compilation errors.

...除非：

$ perl -Mstrict -MData::Dumper -e'
    sub foo { 1 }
    sub bar { 1 }

    my %h;
    $h{foo-bar} = 1;
    print Dumper \%h
'
Ambiguous use of -bar resolved as -&bar() at -e line 1.
$VAR1 = {
          '1' => 1  # oops!
        };

故事的寓意？总是use strict;，并且总是引用不是identifiers 的哈希键（标识符只包含字母、数字和下划线，并且第一个字符不能是数字）。