SQL Server 错误。标识列的显式值....只能在使用列列表并且 IDENTITY_INSERT 为 ON 时指定

Question

我正在尝试创建程序，该程序正在生成错误说明

表tblRegisterUser中标识列的显式值只能在使用列列表和IDENTITY_INSERT is ON时指定。

我试图用INDENTITY_INSERT to ON 包围插入语句，但这也不起作用。我遗漏了什么还是我包含的子查询有错误？

下面是存储过程

CREATE PROCEDURE dbo.spInsertUserRegister
(
    @FirstName nvarchar(50),
    @LastName nvarchar(50),
    @Username nvarchar(50),
    @Password nvarchar(50),
    @Designation nvarchar(50),
    @Department nvarchar(50),
    @IsAdmin bit
)
AS
BEGIN
    INSERT INTO tblRegisterUser Values
    (
        @FirstName, @LastName, @Username, @Password,@Designation,@Department,@IsAdmin
    )
    DECLARE @UID INT
    SET @UID = @@IDENTITY
    INSERT INTO tblLogin(Username,Password,UID,IsAdmin) 
    Values(@Username, @Password, @UID,(SELECT IsAdmin FROM tblRegisterUser WHERE     Username=@Username AND Password=@Password))
END

Answer 1

如果tblRegisterUser 表的结构类似于

ID int primary_key autoincrement
FirstName varchar
LastName varchar 
Username varchar
Password varchar
Designation varchar
Department varchar
IsAdmin bit

这个说法是错误的：

INSERT INTO tblRegisterUser Values
(
    @FirstName, @LastName, @Username, @Password, 
    @Designation,@Department,@IsAdmin
)

您应该使用明确的列列表来指定列：

INSERT INTO tblRegisterUser 
(  FirstName, LastName, Username, Password,
   Designation, Department, IsAdmin) 
VALUES 
(
    @FirstName, @LastName, @Username, @Password, 
    @Designation,@Department,@IsAdmin
)

这样 ID 字段会自动填充，@@Identity 语句应该会正确返回它。

---

也就是说，SQL Server has a few functions 返回为最后一行生成的 ID，每行都有自己的特定优势和劣势。

基本上：

• 如果您不使用触发器，@@IDENTITY 可以工作
• SCOPE_IDENTITY() 适用于您明确调用的代码。
• IDENT_CURRENT(‘tablename’) 适用于所有范围内的特定表。

在几乎所有情况下，SCOPE_IDENTITY() 都是您所需要的，使用它是一个好习惯，与其他选项相反。
here 也可以很好地讨论这些方法的优缺点。

复制自this answer

Answer 2

试试这个 -

CREATE PROCEDURE dbo.spInsertUserRegister 
(
    @FirstName NVARCHAR(50),
    @LastName NVARCHAR(50),
    @Username NVARCHAR(50),
    @Password NVARCHAR(50),
    @Designation NVARCHAR(50),
    @Department NVARCHAR(50),
    @IsAdmin BIT
)
AS BEGIN

    INSERT INTO dbo.tblRegisterUser (FirstName, LastName, Username, [Password], Designation, Department, IsAdmin)
    SELECT @FirstName, @LastName, @Username, @Password, @Designation, @Department, @IsAdmin

    DECLARE @ID BIGINT
    SELECT @ID = SCOPE_IDENTITY()

    --SET IDENTITY_INSERT dbo.tblLogin ON;

    INSERT INTO dbo.tblLogin (UserName, [password], [uid], IsAdmin)
    SELECT @Username, @Password, @ID, IsAdmin 
    FROM tblRegisterUser 
    WHERE UserName = @Username 
        AND [password] = @Password

    --SET IDENTITY_INSERT dbo.tblLogin OFF;

END