如何在 Perl 中同时删除重复项和排序？

Question

我有一个这样的数组

@uniqarr = qw(error 0 goodrecordno:6123, error 0 goodrecordno:6143, error 1 goodrecordno:10245, error 1 goodrecordno:10678, error 1 goodrecordno:10698, error 2 goodrecordno:16245, error 2 goodrecordno:16123);

我想要 o/p 为

error 0 goodrecordno:6123
error 1 goodrecordno:10245 
error 2 goodrecordno:16123

即每个错误都有相应的最低记录号。 任何人都可以在不使用 cpan 模块的情况下帮助我

提前致谢。

Answer 1

这是基本的最小-最大问题，您会在 Perl 入门书籍中找到。您遍历所有元素并记住哪个元素是最低的。这比排序要好得多，排序是为您将所有元素按顺序排列而设计的，这不是您所追求的。

use strict;
use warnings;

# I'll assume those commas were a mistake. You don't need to separate
# items with commas in a quotewords list
# If I'm wrong, the process is the same although the data massaging
# will be a little different
my @elements = qw(
    error 0 goodrecordno:6123
    error 0 goodrecordno:6143
    error 1 goodrecordno:10245 
    error 1 goodrecordno:10678 
    error 1 goodrecordno:10698 
    error 2 goodrecordno:16245 
    error 2 goodrecordno:16123
    );

my %lowest;
while( my( $error, $number, $goodrecno ) = splice @elements, 0, 3, () )
    {
    my( $recno ) = $goodrecno =~ /(\d+)/;

    # This hash remembers the lowest $recno. If you find another
    # a lower number, you replace the previous value.
    $lowest{$number} = $recno if( 
        ! exists $lowest{$number} 
            ||
        $recno < $lowest{$number}
        );
    }

创建具有最低元素的哈希后，您只需将其打印出来：

foreach my $number ( sort { $a <=> $b } keys %lowest ) {
    print "error $number goodrecordno:$lowest{$number}\n";
    };

这将为您提供您正在寻找的输出：

error 0 goodrecordno:6123
error 1 goodrecordno:10245
error 2 goodrecordno:16123

这是此类问题的基本模板。第 1 步：扫描数据以记住您想要的内容，使用哈希来键入这些数据。第二步：输出哈希的内容。

Answer 2

要去除重复，最好的方法是使用List::MoreUtils的uniq，：

use List::MoreUtils 'uniq';
my @unique_list = uniq @list;

或没有 CPAN（尽管这很少需要）：

my %values;
@values{@list} = ();
my @unique_list = keys %values;

您可以使用内置函数 sort 对任何列表进行排序 -- 请参阅 perldoc -f sort 和 perldoc -q 'How do I sort an array'。

---

顺便说一句，您引用的数据与您描述的行为不符。如果将数组声明为

@uniqarr = qw(error 0 goodrecordno:6123, error 0 goodrecordno:6143, error 1 goodrecordno:10245, error 1 goodrecordno:10678, error 1 goodrecordno:10698, error 2 goodrecordno:16245, error 2 goodrecordno:16123);

...那么它的内容将包含：

(
  'error',
  '0',
  'goodrecordno:6123,',
  'error',
  '0',
  'goodrecordno:6143,',
  'error',
  '1',
  'goodrecordno:10245,',
  'error',
  '1',
  'goodrecordno:10678,',
  'error',
  '1',
  'goodrecordno:10698,',
  'error',
  '2',
  'goodrecordno:16245,',
  'error',
  '2',
  'goodrecordno:16123'
);

您需要做的是将数据读入哈希表，然后根据您的标准进行解析。我不能走得更远，因为根本不清楚你在找什么。请阅读 perldoc perldata 和 perldoc perldsc 以了解有关 Perl 数据结构的更多信息。

Answer 3

正如其他人已经指出的那样，您的第一个问题是qw() 不适合建立此数组。

有多种正确的方法，我将在此处使用哈希数组，这是更详细的选项，将技术修改为您选择的任何结构都相当容易。

@uniqarr = (
  { error => 0, goodrecordno => 6123, },
  { error => 0, goodrecordno => 6143, },
  { error => 1, goodrecordno => 10245, },
  { error => 1, goodrecordno => 10678, },
  { error => 1, goodrecordno => 10698, },
  { error => 2, goodrecordno => 16245, },
  { error => 2, goodrecordno => 16123, },
);

然后提取每个具有最低 goodrecordno 的错误实例，我们可以执行以下操作。

首先我们从 List::Util 中导入 min。这个模块是核心 Perl，不需要 CPAN。

然后重构输入@uniqarr。对于我们想要按错误值分组的内容要容易得多。所以 by_error 是数组的散列。哈希的键是错误值，数组包含所有的goodrecordno值。

最后我们产生了想要的输出。遍历散列意味着我们正在迭代每个错误值，排序以提供正确的输出顺序。然后我们提取最小的goodrecordno值。这只是留下打印输出。

use List::Util qw(min); # In core Perl, not CPAN

# Restructure input
my %by_error; # Hash with error as key, array of goodrecordno as value.
foreach (@uniqarr) {
  push @{$by_error{$_->{error}}}, $_->{goodrecordno};
}

# Output as desired
foreach my $error (sort keys %by_error) {
  my $min_no = min @{$by_error{$error}};
  print "error $error goodrecordno:$min_no\n";
}