当多列中的单元格为空白或 0 时删除整行

Question

我正在尝试编写一个基本上查看第 13-33 行的代码，如果 B-M 列中的单元格全部为空白且 A 列不为空白，则删除整行。

我在下面编写的第一个代码仅在 B 列中的单元格为空白时删除整行，但我需要 B-M 中的所有单元格为空白才能删除整行。

Sub scheduleA()

Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual

Sheets("Schedule A Template").Select

Dim RowstoDelete As Long
x = 33
For RowstoDelete = Cells(x, 2).End(xlUp).Row To 13 Step -1

If (Cells(RowstoDelete, 2).Value = "0") And (Cells(RowstoDelete, 1).Value <> "") Then
        Rows(RowstoDelete).Delete Shift:=xlUp
    End If


Next RowstoDelete
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True

End Sub

我也尝试在下面的代码中以不同的方式编写它，但无法达到预期的结果。

Sub DeleteRows()


Dim i As Integer

For i = 33 To 13 Step -1
  If WorksheetFunction.CountA(Range("B" & i, "M" & i)) = 0 And WorksheetFunction.CountA(Range("A" & i)) <> "" Then
     Rows(i).EntireRow.Delete
    End If

Next i

End Sub

请帮忙！

Answer 1

您删除行的条件是：A 列不为空，B 到 M 列为空。那么这样的事情应该可以解决问题：

Sub ScheduleA()
    On Error GoTo errHandler

    Const TOP_ROW As Long = 13
    Const BOTTOM_ROW As Long = 33

    Dim rowIndex As Long

    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual

    With ThisWorkbook.Worksheets("Schedule A Template")
        For rowIndex = .Cells(BOTTOM_ROW, "A").End(xlUp).Row To TOP_ROW Step -1
            If Not IsEmpty(.Cells(rowIndex, "A").Value2) Then '...column A is not blank.
                If Application.WorksheetFunction.CountA(.Range(.Cells(rowIndex, "B"), .Cells(rowIndex, "M"))) = 0 Then '...all cells on row rowIndex from columns B to M are blank.
                    .Rows(rowIndex).Delete Shift:=xlUp
                End If
            End If
        Next
    End With

Cleanup:
    On Error Resume Next
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
    Exit Sub

errHandler:
    MsgBox Err.Description, vbExclamation + vbOKOnly, "Error"
    Resume Cleanup
End Sub

注意.Select 不见了；你几乎不需要选择任何东西来完成工作。不依赖选择将使您的代码更加健壮。在上面的代码中，With 块告诉其中的代码在表达式以句点开头时引用目标工作表，例如 .Cells。

此外，在关闭 ScreenUpdating 和 Calculation 时，系统地包括错误处理以重新打开它们。这样，如果出现问题，您的代码不会使 Excel 处于不良状态。

最后，您可以在工作表的（名称）属性下的“属性”窗口中，直接使用它们的代码名（从 VBA 编辑器中看到）来引用它们，而不是通过其选项卡的名称来引用它们（按 Ctrl+R 显示 Project Explorer，单击 Microsoft Excel Objects 节点下的工作表，然后按 F4 显示 Properties 窗口）。您可以更改此值；我通常会将其更改为 shtScheduleATemplate。然后，With 行可以重写为：

With shtScheduleATemplate

...即使您从 Excel 更改了工作表的名称，它仍然有效。

编辑：在您的问题代码中，您在确定在哪个底行索引处开始循环时检查 B 列。但是，这样做可能会遗漏一些应该删除的行。我已将答案更改为在 A 列中进行检查：

For rowIndex = .Cells(BOTTOM_ROW, "A").End(xlUp).Row To TOP_ROW Step -1