SAS 等价于 R 的 is.element()

Question

今天第一次打开sas，正在看同事写的一些代码。

假设我有一些数据 (import) 出现重复，但我只想要那些具有唯一编号的数据，名为 VTNR。

首先她寻找唯一的数字：

    data M.import;
    set M.import;

    by VTNR;
    if first.VTNR=1 then unique=1;
    run;

然后她用重复的数字创建一个表格：

    data M.import_dup1;
    set M.import;

    where unique^=1;
    run;

最后是一个包含所有重复项的表。 但在这里她真的是对数字进行硬编码，例如：

    data M.import_dup2;
    set M.import;
    where VTNR in (130001292951,130100975613,130107546425,130108026864,130131307133,130134696722,130136267001,130137413257,130137839451,130138291041);
    run;

我相信一定有更好的方法。

由于我只熟悉 R，所以我会写如下内容：

import_dup2 <- subset(import, is.element(import$VTNR, import_dup1$VTNR))

我想 sas 也必须有类似 $ 的东西？

Answer 1

在我看来，它是最直接的 R 代码翻译

import_dup2 <- subset(import, is.element(import$VTNR, import_dup1$VTNR))

将使用 SQL 代码

proc sql;
 create table import_dup2 as 
   select * from import
   where VTNR in (select VTNR from import_dup1)
 ;
quit;

但是，如果您的目的是在 IMPORT 中找到每个 VTNR 值具有多个观察值的观察值，则无需先创建其他表。

data import_dup2 ;
  set import;
  by VTNR ;
  if not (first.VTNR and last.VTNR);
run;

Answer 2

我会使用 PROC SORT 中的选项。 确保指定 OUT= 数据集，否则您将覆盖原始数据。

/*Generate fake data with dups*/
data class;
set sashelp.class sashelp.class(obs=5);
run;

/*Create unique and dup dataset*/
proc sort data=class nouniquekey uniqueout=uniquerecs out=dups;
by name;
run;

/*Display results - for demo*/
proc print data=uniquerecs;
title 'Unique Records';
run;

proc print data=dups;
title 'Duplicate Records';
run;

Answer 3

上述解决方案可以为您提供重复但不是唯一值。在 SAS 中有很多可能的方法来实现这两者。 SQL 解决方案非常容易理解。

proc sql;
create table no_duplicates as
    select *
        from import
        group by VTNR
        having count(*) = 1
    ;
create table all_duplicates as
    select *
        from import
        group by VTNR
        having count(*) > 1
    ;
quit;

Answer 4

我会使用 Reeza 或 Tom 的解决方案，但为了完整起见，最类似于 R 的解决方案（以及您预先存在的代码）将是三个步骤。再说一次，我不会在这里使用它，因为它是你可以更轻松地完成的工作，但这个概念在其他情况下很有帮助。

首先，获取重复数据集 - 她的方法或 proc sort。

proc sort nodupkey data=have out=nodups dupout=dups;
  by byvar;
run;

然后将它们拉入宏列表：

proc sql;
  select byvar 
    into :duplist separated by ','
    from dups;
quit;

然后你将它们放在&duplist. 中并可以像这样使用它们：

data want;
  set have;
  if not (byvar in &duplist.);
run;

Answer 5

data want;
   set import;
   where VTNR in import_dup1;
run;