Oracle：在整个数据库中搜索字符串：错误 ORA-00911

Question

我创建了下面的 PL/SQL 存储过程，用于在整个 Oracle11g 数据库中搜索字符串 (srchstr)，并将找到该字符串的表和列返回到名为 VALUESEARCHRESULTS 的表中。

该过程已以用户身份通过​​ SQL Developer 在 Oracle XE 中成功运行。但是，当尝试在 Oracle11g 中以用户 SYS 的身份运行模式 ABC 时，我收到以下错误：

ORA-00911：无效字符 原因：标识符不能以字母和数字以外的任何 ASCII 字符开头。在第一个字符之后也允许使用 $#_。用双引号括起来的标识符可以包含除双引号之外的任何字符。替代引号 (q"#...#") 不能使用空格、制表符或回车作为分隔符。对于所有其他上下文，请参阅 SQL 语言参考手册。

有人知道为什么会这样吗？请在下面查看我的代码。

CREATE OR REPLACE PROCEDURE ABC.FIND_STRING(p_str IN VARCHAR2) authid current_user is
  l_query    clob;
  srchstr    varchar2(30) := '';
  r_cname    varchar2(30) := '';
  l_case     clob;
  l_runquery boolean;
  l_tname    varchar2(30);
  l_cname    varchar2(30);
begin
   dbms_application_info.set_client_info( '%' || upper(p_str) || '%' );

   for x in (select * from user_tables)
   loop
       l_query := 'select ''' || x.table_name || ''', $$
                     from ' || x.table_name || '
                    where rownum = 1 and ( 1=0 ';
       l_case := 'case ';
       l_runquery := FALSE;
       for y in ( select *
                    from user_tab_columns
                   where table_name = x.table_name
                     and (data_type in('CHAR', 'DATE', 'FLOAT', 'NCHAR', 'NUMBER', 'NVARCHAR2', 'VARCHAR2' )
                       or data_type like 'INTERVAL%' or data_type like 'TIMESTAMP%' )
                )
       loop
           l_runquery := TRUE;
           l_query := l_query || ' or upper(' || y.column_name ||
                      ') like userenv(''client_info'') ';
           l_case := l_case || ' when upper(' || y.column_name ||
                     ') like userenv(''client_info'') then ''' ||
                     y.column_name || '''';
       end loop;
       if ( l_runquery )
       then
           l_case := l_case || ' else NULL end';
           l_query := replace( l_query, '$$', l_case ) || ')';
           begin
              execute immediate l_query into l_tname, l_cname;
              r_cname := l_cname;
              dbms_application_info.read_client_info(srchstr);
              insert into ABC.ValueSearchResults (resulttable, resultcolumn, searchstring) values (x.table_name, r_cname, srchstr);
               dbms_output.put_line
               ( srchstr || ' found in ' || l_tname || '.' || l_cname );
           exception
               when no_data_found then
                   dbms_output.put_line
                   ( srchstr || ' has no hits in ' || x.table_name );
           end;
          end if;
        end loop;
       end;

EDIT：上面的存储过程编译没有错误。下面的代码通过将值从表传递到存储过程来执行存储过程。运行以下代码时显示错误：

BEGIN
   FOR c IN (SELECT ControlValue FROM ABC.ControlValues) LOOP
       ABC.FIND_STRING(c.ControlValue);
   END LOOP;
END;

Answer 1

我找到了解决我最初提出的问题的方法。

错误原因：未指定架构；只抓取用户特定的表格。

虽然存储过程在部署为用户 ABC 时会执行，但在作为用户其他 ABC 运行存储过程时会产生错误。看起来相同的表名存在于多个模式中。因此，添加 OWNER 变量指定了与表名关联的架构并消除了错误。

此外，该过程最初是在搜索 USER_TABLES。这将结果限制为仅当前模式的表。通过将 USER_TABLES 替换为 DBA_TABLES，存储过程的搜索跨越了数据库的所有表。

更正后的代码见下文：

CREATE OR REPLACE
PROCEDURE FIND_STRING(
    p_str IN VARCHAR2) authid current_user
IS
  l_query CLOB;
  srchstr VARCHAR2(100) := '';
  r_cname VARCHAR2(100) := '';
  l_case CLOB;
  l_runquery BOOLEAN;
  l_tname    VARCHAR2(100);
  l_cname    VARCHAR2(100);
BEGIN
  dbms_application_info.set_client_info( '%' || upper(p_str) || '%' );
  FOR x  IN
  (SELECT *
  FROM dba_tables
  WHERE table_name    <> 'CONTROLVALUES'
  AND table_name      <> 'VALUESEARCHRESULTS'
  AND tablespace_name <> 'SYSTEM'
  AND tablespace_name <> 'SYSAUX'
  AND tablespace_name <> 'TEMP'
  AND tablespace_name <> 'UNDOTBS1'
  )
  LOOP
    l_query    := 'select ''' || x.owner || '.' || x.table_name || ''', $$                         
from ' || x.owner || '.' || x.table_name || '                         
where rownum = 1 and ( 1=0 ';
    l_case     := 'case ';
    l_runquery := FALSE;
    FOR y  IN
    (SELECT *
    FROM dba_tab_columns
    WHERE table_name = x.table_name
    AND owner        = x.owner
    AND (data_type  IN ( 'CHAR', 'DATE', 'FLOAT', 'NCHAR', 'NUMBER', 'NVARCHAR2', 'VARCHAR2' )
    OR data_type LIKE 'INTERVAL%'
    OR data_type LIKE 'TIMESTAMP%' )
    )
    LOOP
      l_runquery := TRUE;
      l_query    := l_query || ' or upper(' || y.column_name || ') like userenv    (''client_info'') ';
      l_case     := l_case || ' when upper(' || y.column_name || ') like userenv    (''client_info'') then ''' || y.column_name || '''';
    END LOOP;
    IF ( l_runquery ) THEN
      l_case  := l_case || ' else NULL end';
      l_query := REPLACE( l_query, '$$', l_case ) || ')';
      BEGIN
        EXECUTE immediate l_query INTO l_tname, l_cname;
        r_cname := l_cname;
        dbms_application_info.read_client_info(srchstr);
        INSERT
        INTO VALUESEARCHRESULTS
          (
            resulttable,
            resultcolumn,
            searchstring
          )
          VALUES
          (
            x.table_name,
            r_cname,
            srchstr
          );
        dbms_output.put_line ( srchstr || ' found in ' || l_tname || '.' || l_cname );
      EXCEPTION
      WHEN no_data_found THEN
        dbms_output.put_line ( srchstr || ' has no hits in ' || x.owner || '.' || x.table_name );
      END;
    END IF;
  END LOOP;
END;