Mac Automator：从字符串中获取文件

Question

我正在尝试通过自动化服务创建一个快捷方式，该服务会将所选文件向上移动到目录中。如下：

1. 获取选定的 Finder 项目

2. 获取变量Path的值

3. 运行 Applescript：

   on join(someList, delimiter)
   set prevTIDs to AppleScript's text item delimiters
       set AppleScript's text item delimiters to delimiter
       set output to "" & someList
       set AppleScript's text item delimiters to prevTIDs
       return output
   end join
   to split(someText, delimiter)
       set AppleScript's text item delimiters to delimiter
       set someText to someText's text items
       set AppleScript's text item delimiters to {""}
       return someText
   end split
   on run {input, parameters}
       set pathToMe to POSIX path of (item 1 of input as text)
       set newPath to split(pathToMe, "/")
       set revPath to reverse of newPath
       set restList to rest of revPath
       set restList to rest of restList
       set joinPath to join(reverse of restList, "/")
       set source to POSIX file joinPath
       return source
   end run
   

4. 设置变量Parent的值

5. 将 Finder 项目移至 Parent

Applescript 解析Path 中的第一个文件路径以查找项目的祖父母，并将其作为 POSIX 文件字符串返回。问题是“移动查找器”操作只接受文件/文件夹。如何使用结果字符串选择目标父文件夹，以便将其传递给“移动查找器”操作？

我尝试过的事情：

• 在Run Bash Script 中使用mv：Run Applescript 操作似乎没有向Run Bash Script 返回任何内容；设置为作为参数输入，“$@”始终为空。
• 在Run Applescript 中执行tell finder。没有错误或警告，只是没有任何反应。
• 手动设置parent 变量的值。

提前致谢！

Answer 1

在 list 中返回 alias 类型的路径，而不是 posix file

on run {input, parameters}
    set pathToMe to (item 1 of input) as text
    set f to my getParent(pathToMe, ":")
    return {f as alias}
end run

to getParent(someText, delimiter)
    set prevTIDs to AppleScript's text item delimiters
    set AppleScript's text item delimiters to delimiter
    set n to -2
    if someText ends with ":" then set n to -3
    set t to text 1 thru text item n of someText
    set AppleScript's text item delimiters to prevTIDs
    return t
end getParent

Answer 2

我更喜欢在 applescript 中完成这一切，所以试试这段代码。我没有测试它，但它应该可以工作。您仍然可以使用 applescript 操作将其添加到 automator，但您不需要所有其他操作。它会自己做所有事情。祝你好运。

tell application "Finder"
    set theSelection to get selection
    set parentFolder to container of (item 1 of theSelection)
    move theSelection to parentFolder
end tell