VBA - 将 Excel 数据导入 MS Project

Question

我正在尝试从 Excel 中获取数据表并将其导入 MS Project

这是我在 Excel 中的截图：

CC：列标题的 Excel 表格：WBS、任务名称、开始日期、完成日期、工期、工时和资源名称，其中包含独立于资源名称分配的数据行。

这是我正在寻找能够从 Excel 生成到 MS Project 的 VBA 代码的屏幕截图：

CC：MS 项目文件显示 WBS、任务名称、开始日期、完成日期、持续时间、工作和资源名称列，其中资源名称按 WBS 分组。

我尝试过复制和粘贴，但 VBA 必须有更好的选择（我希望？）

如果有问题，我很乐意回答。

非常感谢任何人能给我的帮助！

编辑： 这是我现在拥有的 VBA：

Sub ExceltoProject()
Dim pjapp As Object
Dim strValue, strStartDate, strEndDate, Strresource As String
Dim newproj
Set pjapp = CreateObject("MSProject.Application")
If pjapp Is Nothing Then
MsgBox "Project is not installed"
Exit Sub
End If
pjapp.Visible = True

Set newproj = pjapp.Projects.Add
newproj.Title = "ExcelExtract"
Set ActiveProject = newproj
For i = 2 To 4

strWBS = Worksheets("LABOR_IMS_INPUT").Range("A" & i)
strTaskName = Worksheets("LABOR_IMS_INPUT").Range("B" & i)
strStartDate = Worksheets("LABOR_IMS_INPUT").Range("C" & i)
strEndDate = Worksheets("LABOR_IMS_INPUT").Range("D" & i)
strDuration = Worksheets("LABOR_IMS_INPUT").Range("E" & i)
Strresource = Worksheets("LABOR_IMS_INPUT").Range("F" & i)
strWork = Worksheets("LABOR_IMS_INPUT").Range("G" & i)

newproj.Tasks.Add (strValue & " " & Strresource)
newproj.Resources.Add.Name = Strresource
newproj.Tasks(i - 1).ResourceNames = Strresource
Next i
End Sub

Public Function ExistsInCollection(pColl, ByVal pKey As String) As Boolean
On Error GoTo NoSuchKey
If VarType(pColl.Item(pKey)) = vbObject Then
' force an error condition if key does not exist
End If
ExistsInCollection = True
Exit Function

NoSuchKey:
ExistsInCollection = False
End Function

但这就是我得到的：

CC: Excel file and MS Project file. MS Project file only has "resource sheet name" data.

任何想法正在发生的事情。是我做错了吗？

抱歉之前的问题清晰，我有视力障碍，正在尝试编码！

Answer 1

此代码将从 Excel 工作表中获取数据以创建新的项目计划。无需同时设置 Finish 和 Duration 字段，因为 Finish 日期将由 Start date 和 Duration 决定。

Sub ExceltoProject()
Dim pjapp As Object
Dim newproj As Object

Set pjapp = CreateObject("MSProject.Application")
If pjapp Is Nothing Then
    MsgBox "Project is not installed"
    Exit Sub
End If
pjapp.Visible = True

Set newproj = pjapp.Projects.Add
newproj.Title = "ExcelExtract"

Dim wst As Worksheet
Set wst = ThisWorkbook.Worksheets("LABOR_IMS_INPUT")

Dim i As Long
For i = 2 To 4
    newproj.Tasks.Add
    newproj.Tasks(i - 1).Name = wst.Cells(i, 2)
    newproj.Tasks(i - 1).WBS = wst.Cells(i, 1)
    newproj.Tasks(i - 1).Start = CDate(wst.Cells(i, 3))
    newproj.Tasks(i - 1).Duration = wst.Cells(i, 5) & "d"
    newproj.Tasks(i - 1).ResourceNames = wst.Cells(i, 7)
    newproj.Tasks(i - 1).Work = wst.Cells(i, 6) & "h"
Next i

End Sub