恢复到未按预期工作的标签

Question

我在使用 Resume 时遇到了问题，虽然我通过使用 On Error GoTo 找到了另一个解决方案，但我仍然对为什么下面的代码不起作用感到困惑。发生初始错误是因为工作表名称“Sheet_1”已被占用。这意味着，在监视窗口中，在执行 Resume NameAgain 之前，err.number 的值为 1004。不是清除错误并跳回标签，而是发生错误 20（无错误恢复），代码移至 End If 行。

鉴于存在活动错误 1004，我无法理解为什么它的行为就像没有错误一样。我已经在该站点上搜索了错误 20 问题，但没有什么能真正为我解决这个问题，也没有让我理解它背后的逻辑。非常感谢任何帮助。

Sub ErrorTest()

Dim i as integer:i=1

NameAgain: On Error Resume Next
Worksheets("Main").Name = "Sheet_" & i
If Err.Number = 1004 Then
  i = i + 1
  Resume NameAgain
End If

End Sub

paxdiablo 评论后更新：

以上是试图复制但简化我遇到的问题的糟糕尝试。我正在使用的代码部分如下：

Activate CheckBook to use ActiveWindow
  CheckBook.Activate
  Set DestSheet = CheckBook.Worksheets.Add(After:=CheckBook.Sheets(1))
  On Error Resume Next
  v = 1
NameAgain:  DestSheet.Name = ExpBookName & "_" & v
                If Err.Number = 1004 Then
                    v = v + 1
                    Resume NameAgain
                End If
            On Error GoTo 0
            ActiveWindow.DisplayGridlines = False
            Set DestCell = DestSheet.Range("A2")

所以解决方法是将 On Error Resume Next 移动到标签行并使用 GoTo 代替 Resume。

Answer 1

resume 语句是一种从错误处理程序内返回到主（非错误处理）代码中的某个点并继续执行的方法。

在这种情况下，您明确声明您希望在发生错误时自动resume next。

这在功能上等同于（类似VB的伪代码）：

line:
    on error goto handler
    cause error
    resume line ' not in an error handler at this point '

handler:
    resume next

所以从技术上讲，在您尝试resume 到标签时，您并不是一个错误处理程序。

正确 声明您正在尝试做的事情将是一个简单的goto 而不是resume。

Answer 2

更正确的解决方案是编写不会故意产生错误或不使用 Goto 的代码。

Public Function GetNextSheetName(ByVal ipWb As Excel.Workbook, ByVal ipStemName As String) As String

    Dim mySheet As Variant
    Dim mySD As Scripting.Dictionary
    Set mySD = New Scripting.Dictionary
    For Each mySheet In ipWb.Sheets
    
        ' mySd.Count is a dummy entry to satisfy
        ' the Key and Item requirements for .Add.
        ' we are only interested in the Keys
        ' for use with the .Exists method later
        mySD.Add mySheet.Name, mySD.Count
        
    Next
    
    Do
    
        DoEvents
        
        Dim myIndex As Long
        myIndex = myIndex + 1
        
        Dim myNextSheetName As String
        myNextSheetName = ipStemName + "_" & CStr(myIndex)
        
    Loop While mySD.Exists(myNextSheetName)
    
    GetNextSheetName = myNextSheetName
       
End Function

现在允许

    Set DestSheet = checkbook.Worksheets.Add(After:=checkbook.Sheets(1))
    DestSheet.Name = GetNextSheetName(checkbook, ExpBookName)
    ActiveWindow.DisplayGridlines = False
    Set DestCell = DestSheet.Range("A2")