将带有 & 的 regsub 匹配传递给过程（正在使用 Tcl）

Question

我想检查一个逗号分隔的字符串，并用更多逗号分隔的元素替换匹配项。

即 regsub 之后的 5-A,B 应该给我 1-A,2-A,3-A,4-A,5-A,B

以下内容对我不起作用，因为 & 被作为实际 & 而不是实际匹配传递：

regsub -all {\d+\-\w+} $string [myConvertProc &]

但是不尝试传递 & 并直接使用它是有效的：

regsub -all o "Hello World" &&&
> Hellooo Wooorld

不确定我在尝试将值传递给 myConvertProc

时做错了什么

编辑： 我认为我最初的问题是 [myConvertProc &] 被首先评估，所以我实际上将 '&' 传递给过程。

如何在正则表达式领域解决这个问题？有可能吗？

编辑 2： 我已经使用拆分列表上的 foreach 解决了它，所以我只是想看看这是否可以在 regsub 中实现。谢谢！

Answer 1

您的第一次编辑是正确的：问题是regsub 的每个参数在执行命令之前都经过了全面评估。

一种解决方法是在字符串中插入一个命令替换字符串，然后在其上使用subst：

set string [regsub -all {\d+\-\w+} $string {[myConvertProc &]}]
# -> [myConvertProc 5-A],B
set string [subst $string]
# -> 1-A,2-A,3-A,4-A,5-A,B

这只有在string 中没有其他需要替换的内容时才有效（但您当然可以关闭变量和反斜杠替换）。

foreach 解决方案要好得多。 foreach 的另一种解决方案是迭代 regexp -indices -inline -all 的结果，但如果可行的话，最好对拆分列表的各个部分进行迭代。

更新：

一个典型的foreach 解决方案是这样的：

set res {}
foreach elem [split $string ,] {
    if {[regexp -- {^\d+-\w+$} $elem]} {
        lappend res [myConvertProc $elem]
    } else {
        lappend res $elem
    }
}
join $res ,

也就是说，您通过查看原始列表中的每个元素来收集结果列表。如果元素符合您的要求，则转换它并将结果添加到结果列表中。如果元素不匹配，只需将其添加到结果列表中即可。

在 Tcl 8.6 中可以稍微简化一下：

join [lmap elem [split $string ,] {
    if {[regexp -- {^\d+-\w+$} $elem]} {
        myConvertProc $elem
    } else {
        set elem
    }
}] ,

这是同样的事情，但lmap 命令会为您处理结果列表。

文档：foreach、lappend、lmap、regexp、regsub、set、split、subst