在 VBA 的 access 2007 中编辑后如何保存 Excel 电子表格答案

【问题标题】：how do i save a excel spreadsheet after editing it in access 2007 in VBA在 VBA 的 access 2007 中编辑后如何保存 Excel 电子表格
【发布时间】：2014-03-19 04:32:09
【问题描述】：

我试图让 Access 2007 打开 Excel 电子表格，将数据添加到单元格，然后保存电子表格。我在 Access 2007 表单中有一个按钮，可以激活以下代码。这是我到目前为止所拥有的，但每个“保存命令”都不起作用。有人知道用什么吗？

Private Sub buttonExcel_Click()
    Dim oExcel As Object
    Dim oBook As Object
    Dim oSheet As Object

    ' Create a New Excel WorkBook
    Set oExcel = CreateObject("Excel.Application")

    ' Optional, Open a current Workbook from a file directory
    oExcel.Workbooks.Open ("Z:\08_Volume Management\ACCESS\EMAILTEMPLATES\test.xlsx")

    ' Make the Excel Workbook visible to the users
    oExcel.Visible = True

    ' Define the Workbook from Excel
    Set oBook = oExcel.ActiveWorkbook

    ' Define the Workskeet from the Workbook (1="Sheet1", 2="Sheet2", etc...)
    Set oSheet = oBook.Worksheets(1)

    ' Write Data to the Worksheet (Block "A1" is the first row, first column)
    oSheet.Range("A1").Value = "Hello World"

    ' Save the Excel Workbook
    oExcel.SaveAs ("Z:\08_Volume Management\ACCESS\EMAILTEMPLATES\test.xlsx") ' DOESNT WORK
    oExcel("Z:\08_Volume Management\ACCESS\EMAILTEMPLATES\test.xlsx").Save ' DOESNT WORK
    oBook.SaveAs ("Z:\08_Volume Management\ACCESS\EMAILTEMPLATES\test.xlsx") ' DOESNT WORK
    oBook("Z:\08_Volume Management\ACCESS\EMAILTEMPLATES\test.xlsx").Save ' DOESNT WORK

    ' Closes Excel as asks to save the Workbook
    oExcel.Workbooks.Close

    ' Quit Excel
    'oExcel.Quit
End Sub

谢谢！

【问题讨论】：

oBook.Save 应该这样做。

标签： excel ms-access vba ms-access-2007

【解决方案1】：

Private Sub buttonExcel_Click()
    Dim oExcel As Object
    Dim oBook As Object
    Dim oSheet As Object

    Set oExcel = CreateObject("Excel.Application")

    Set oBook = oExcel.Workbooks.Open ("Z:\08_Volume Management\" & _
                                 "ACCESS\EMAILTEMPLATES\test.xlsx")
    oExcel.Visible = True

    Set oSheet = oBook.Worksheets(1)

    oSheet.Range("A1").Value = "Hello World"

    oBook.Save
    oBook.Close
    'or...
    'oBook.Close True 'True = save changes

    oExcel.Quit

End Sub

【讨论】：