INSERT INTO 语句中的换行符

Question

我已经搜索了所有的板，但找不到有人问如何在 INSERT INTO 语句的代码中进行换行。我尝试了很多变化，我似乎可以让它们中的任何一个起作用。他是我的代码和我正在尝试的示例。我知道这只是一个放错位置的逗号、引号或 & 号。

StrSQL = "INSERT INTO Tbl_Data_Shop & _
(ClaimNumber, ExposureNumber, ClaimSuffix, & _
Shop_Name, Shop_StreetAddress, Shop_City, & _
Shop_State, Shop_Zip, Shop_Phone) & _
"Values 
('" & Forms!Frm_Data_Main!TBClaimNumber & "' & _
"'" & Forms!Frm_Data_Main!TBExposureNumber & "' & _
"'" & Forms!Frm_Data_Main!TBClaimSuffix & "'," & _
"'" & TBSShop_Name & "'," & _
"'" & TBSShop_StreetAddress & "'," & _
"'" & TBSShop_City & "'," & _
"'" & TBSShop_State & "'," & _
"'" & TBSShop_Zip & "'," & _
"'" & TBSShop_Phone & "'");"

Answer 1

再一次，使用parameterization 的行业最佳实践的经典示例，您可以在 MS Access 中使用QueryDefs.Parameters 执行此操作。除了防止 sql 注入之外，您还可以避免使用字符串插值来担心引号或 & 符号，并且可以构建一个更具可读性和可维护性的代码块。

无论使用哪种语言（此处为 VBA），该过程都涉及使用占位符设置准备好的 SQL 语句。然后在不同的步骤中将数据值绑定到占位符以供执行。

SQL

在下面另存为已保存的 MS Access 查询（功能区 > 创建 > 查询 > SQL 视图）。此 SQL 查询使用 PARAMETERS 子句（在 Access SQL 方言中有效）来定义占位符及其类型，然后使用占位符。你可以打破所有你想要的线条！

PARAMETERS TBClaimNumberParam TEXT(255), TBExposureNumberParam TEXT(255), 
           TBClaimSuffixParam TEXT(255), TBSShop_NameParam TEXT(255), 
           TBSShop_StreetAddressParam TEXT(255), TBSShop_CityParam TEXT(255),
           TBSShop_StateParam TEXT(255), TBSShop_ZipParam TEXT(255), 
           TBSShop_PhoneParam TEXT(255); 
INSERT INTO Tbl_Data_Shop (ClaimNumber, ExposureNumber, ClaimSuffix,
                           Shop_Name, Shop_StreetAddress, Shop_City, 
                           Shop_State, Shop_Zip, Shop_Phone)
VALUES (TBClaimNumberParam, TBExposureNumberParam, TBClaimSuffixParam,
        TBSShop_NameParam, TBSShop_StreetAddressParam, TBSShop_CityParam,
        TBSShop_StateParam, TBSShop_ZipParam, TBSShop_PhoneParam)

VBA

在此步骤中，您将上述保存的查询 mySavedQuery 引用到 QueryDef 对象中，该对象随后将 VBA 值绑定到查询的命名参数（在上述 SQL 中定义）。

Dim qdef As QueryDef

Set qdef = CurrentDb.QueryDefs("mySavedQuery")

' BIND VALUES TO PARAMETERS
qdef!TBClaimNumberParam = Forms!Frm_Data_Main!TBClaimNumber
qdef!TBExposureNumberParam = Forms!Frm_Data_Main!TBExposureNumber
qdef!TBClaimSuffixParam = Forms!Frm_Data_Main!TBClaimSuffix
qdef!TBSShop_NameParam = TBSShop_Name
qdef!TBSShop_StreetAddressParam = TBSShop_StreetAddress
qdef!TBSShop_CityParam = TBSShop_City
qdef!TBSShop_StateParam = TBSShop_State
qdef!TBSShop_ZipParam = TBSShop_Zip
qdef!TBSShop_PhoneParam = TBSShop_Phone 

' EXECUTE ACTION
qdef.Execute dbFailOnError

Set qdef = Nothing

Answer 2

将每一行单独设为一个字符串 - 并更正逗号和括号：

StrSQL = "INSERT INTO Tbl_Data_Shop " & _
"(ClaimNumber, ExposureNumber, ClaimSuffix, " & _
"Shop_Name, Shop_StreetAddress, Shop_City, " & _
"Shop_State, Shop_Zip, Shop_Phone) " & _
"Values (" & _
"'" & Forms!Frm_Data_Main!TBClaimNumber & "'," & _
"'" & Forms!Frm_Data_Main!TBExposureNumber & "'," & _
"'" & Forms!Frm_Data_Main!TBClaimSuffix & "'," & _
"'" & TBSShop_Name & "'," & _
"'" & TBSShop_StreetAddress & "'," & _
"'" & TBSShop_City & "'," & _
"'" & TBSShop_State & "'," & _
"'" & TBSShop_Zip & "'," & _
"'" & TBSShop_Phone & "');"

Answer 3

引号和 &s 丢失/错位。但是，出于多种原因，我会使用prepared 声明，即安全性和可管理性。

StrSQL = "INSERT INTO Tbl_Data_Shop & _
(ClaimNumber, ExposureNumber, ClaimSuffix, & _
Shop_Name, Shop_StreetAddress, Shop_City, & _
Shop_State, Shop_Zip, Shop_Phone) & _
 Values ('" & Forms!Frm_Data_Main!TBClaimNumber & "', & _
'" & Forms!Frm_Data_Main!TBExposureNumber & "', & _
'" & Forms!Frm_Data_Main!TBClaimSuffix & "', & _
'" & TBSShop_Name & "', & _
'" & TBSShop_StreetAddress & "', & _
'" & TBSShop_City & "', & _
'" & TBSShop_State & "', & _
'" & TBSShop_Zip & "', & _
'" & TBSShop_Phone & "');"

尝试告诉我们。