Excel 根据标题比较同一行中两列的匹配或差异

Question

Sheet1上有 45 列
每次列不在同一个地方时，在 Sheet1 中有两个重要的列，即 Work Country 和 Base Country，我在其中检查值是否两列的输出相同或不同：如果它们相同，则列 Status 中的输出应为 Local，否则为 Expat。
但是当我尝试计算公式时，结果是 #Name?
你能帮我解决这个问题吗？我附上了我的工作表的屏幕截图。
我的 Excel 文件也包含 VBA 模块，所以我可以使用公式或 VBA 代码。

这是我用过的公式：

=IF(Work Geography,A2)=IFS(Work Country,B2)

Answer 1

这个错误可能有多种原因：

• MS Office Professional Plus 2013 中未定义 IFS 函数，您使用的函数未在您的 Excel 版本中启用。
• 您的公式引用了 Excel 中未定义的名称，您显然使用了命名范围（Work Geography 和 Work Country），但您可能忘记定义它们。
• 有一个错字，它在Work Geography 或Work Country 或两者中，因为名称不能包含空格字符。
• 逻辑有缺陷，对非布尔值使用 IF 函数可能会导致意想不到的结果。

我会使用的公式：

=IF(A2=B2, "Local", "Expat")

感谢@Zac 的澄清。
这是我想出的：

Option Explicit
Sub CheckCountries()
    Dim lRow As Long
    Dim MySheet As Worksheet
    Dim rngGeo As Range, rngCountry As Range, rngStatus As Range
    Dim rngData As Range

    '    Define Sheet1
    Set MySheet = ThisWorkbook.Worksheets("Sheet1")

    '    I assumed headers are constantly on the first row
    '    Find cells with needed headers
    Set rngGeo = MySheet.Rows(1).Find("Work Geography", , xlValues, xlWhole, xlByColumns)
    Set rngCountry = MySheet.Rows(1).Find("Work Country", , xlValues, xlWhole, xlByColumns)
    Set rngStatus = MySheet.Rows(1).Find("Status", , xlValues, xlWhole, xlByColumns)

    '    Your big table, excluding headers
    With MySheet.Range("A1").CurrentRegion
        Set rngData = .Offset(1, 0).Resize(.Rows.Count - 1, .Columns.Count)
    End With
    
    '    Define needed columns
    Set rngGeo = Intersect(rngData, rngGeo.EntireColumn)
    Set rngCountry = Intersect(rngData, rngCountry.EntireColumn)
    Set rngStatus = Intersect(rngData, rngStatus.EntireColumn)

    '    Calculate
    rngStatus.Value _
        = Evaluate("=IF(" & rngGeo.Address & "=" & rngCountry.Address & ", " & _
                        """Local"", " & _
                        """Expat"")")
End Sub