在excel VBA中，将未定义数量的数字添加到加法公式中

Question

我正在努力创建将动态将未定义数量的变量粘贴到公式中的代码。我遇到问题的部分是我拥有的值的数量是未定义的，并且能够将值粘贴到公式中。

例子：

计算 A = (1 + 1) Ans = 2 公式 = 2

计算 B = (3 + 3) Ans = 6 公式 = 2 + 6

Calc C = (4 + 4) Ans = 8 公式 = 2 + 6 + 8

这种方法的好处是，当我点击公式时，我可以看到答案的审计线索。

下面的尝试代码

Dim Ans1 as Integer
Dim Ans2 as Integer

Ans1 = 2
Range("A1").Value = Ans1

Ans2 = 6
Range("A1").Formula = Ans1 + Ans2

更新：

Sub vba_loop_sheets()

Dim i As Long 'Base sheet
Dim ii As Long 'Moving sheet
Dim shtCount As Long
Dim ans As Variant
Dim ans2 As Variant

shtCount = Sheets.count - 1

For i = 7 To shtCount
For ii = i + 1 To shtCount

    If Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value And ans = "" Then
    
    ans = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
    
    ThisWorkbook.Sheets("calc").Range("F5").Value = ans
    
    ElseIf Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value And ans <> "" Then
    
    ans2 = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
    
    ans = ans + ans2
    
    ThisWorkbook.Sheets("calc").Range("F5").Value = ans
    
    End If

Next ii
Next i

End Sub

更新 09/14/21 下午 5:15

Sub vba_loop_sheets()

Dim i As Long 'Base sheet
Dim ii As Long 'Moving sheet
Dim shtCount As Long
Dim ans As Variant
Dim ans2 As Variant

shtCount = Sheets.count - 1

For i = 7 To shtCount
For ii = i + 1 To shtCount

    If Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value And ans = "" Then
    
    ans = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
    
    ThisWorkbook.Sheets("calc").Range("F5").Formula = "=" & ans
    
    ElseIf Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value And ans <> "" Then
    
    ans2 = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
    
    ThisWorkbook.Sheets("calc").Range("F5").Formula = "=" & ans & "+" & ans2
    
    ans = ans + ans2
    
    End If

Next ii
Next i

End Sub

Answer 1

这应该是某种从提供计算的东西中调用的子吗？

对于您更新的公式，如何：

Sub vba_loop_sheets()

Dim i As Long 'Base sheet
Dim ii As Long 'Moving sheet
Dim shtCount As Long
Dim ans As Variant

shtCount = Sheets.Count - 1

For i = 7 To shtCount
    For ii = i + 1 To shtCount
        If Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value And ans = "" Then
            ans = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
            ThisWorkbook.Sheets("calc").Range("F5").Value = "=" & ans
        ElseIf Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value And ans <> "" Then
            ans = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
            Sheets("calc").Range("F5").Formula = Sheets("calc").Range("F5").Formula & "+" & ans
        End If
    Next ii
Next i

End Sub

甚至：

Sub vba_loop_sheets()
Dim i As Long 'Base sheet
Dim ii As Long 'Moving sheet
Dim shtCount As Long, ans As String, outRange As Range
Set outRange = Sheets("calc").Range("F5")
shtCount = Sheets.Count - 1
For i = 7 To shtCount
    For ii = i + 1 To shtCount
        If Sheets(i).Range("B1").Value = Sheets(ii).Range("B1").Value Then
            ans = Abs(Sheets(i).Range("B8").Value - Sheets(ii).Range("B8").Value)
            If outRange = "" Then
                outRange.Value = "=" & ans
            Else
                outRange.Formula = outRange.Formula & "+" & ans
            End If
        End If
    Next ii
Next i
End Sub