解析 XML 的最快方法

Question

我有巨大的 XML 文件，每个大约 1GB。它们太大了，由于数据量大，即使在 Notepad++ 中也无法打开。

我编辑了 XML 并能够通过 DOMDocument60 对其进行解析（感谢 stackflow 提供的帮助）。

我在Improve speed of VBA 阅读了类似的问题，但我仍然无法正确实施，因此需要一些指导。

例如：

1. 如何在 SAX 中加载 xml？在 SAX 中读取之前，我是否需要将其加载到 DOMDocument60 中？
2. 导入后如何在 SAX 中逐行读取？在 DOMDocument60 中，我可以轻松跳转到任何节点，然后循环遍历子节点，但不确定如何在 SAX 中执行此操作？
3. 与 DOMDocument 相比，SAX 解析大型 XML 的时间差是多少？我还没有找到任何关于此的实时示例。
4. 在 VBA 中是否有比 SAX 更好的选择，就像我可以用来加快解析过程的任何其他库一样。

感谢您的建议。 （示例 XML 文件如下）

<ParentNode type="actual">

<SampleObject class="POC" version="XYZ123" distName="Test1" id="Sample">
  <p name="name">POC1</p>
  <p name="object1">0</p>
  <p name="object2">6</p>
  <p name="object3">0</p>
</SampleObject>

<SampleObject class="POC" version="XYZ123" distName="Test2" id="Sample">
  <p name="name">POC1</p>
  <p name="object1">2</p>
  <p name="object2">10</p>
  <p name="object4">4</p>
  <p name="object3">6</p>
</SampleObject>

<SampleObject class="POC" version="XYZ123" distName="Test3" id="Sample">
  <p name="name">POC1</p>
  <p name="object2">90</p>
  <p name="object3">0</p>
</SampleObject>

<SampleObject class="POC" version="XYZ123" distName="Test4" id="Sample">
  <p name="name">POC1</p>
  <p name="object1">2</p>
  <p name="object2">10</p>
  <p name="object4">40</p>
  <p name="object3">61</p>
</SampleObject>

Answer 1

这里是我按照上面发布的链接并使用您的示例 XML 的地方。 只是输出到即时窗口：我不知道你在用提取的数据做什么......

常规模块中的测试方法：

Sub Tester()

    Const FNAME As String = "example.xml"
    Dim rdr As New MSXML2.SAXXMLReader30
    Dim cnth As New ContentHandler

    Set rdr.ContentHandler = cnth
    rdr.parseURL ThisWorkbook.Path & "\" & FNAME  'test xml file is in same folder as the workbook

End Sub

类模块ContentHandler:

Option Explicit

Implements IVBSAXContentHandler

Dim cls, vers, distName, id, pName, pContent
Dim inSO As Boolean, inP As Boolean

Private Sub IVBSAXContentHandler_characters(strChars As String)
    If inP Then Debug.Print "P content:", strChars
End Sub

Private Sub IVBSAXContentHandler_startElement(strNamespaceURI As String, _
                             strLocalName As String, strQName As String, _
                             ByVal oAttributes As MSXML2.IVBSAXAttributes)
    Select Case strLocalName
        Case "SampleObject"
            inSO = True
            cls = oAttributes.getValueFromName("", "class")
            vers = oAttributes.getValueFromName("", "version")
            distName = oAttributes.getValueFromName("", "distName")
            id = oAttributes.getValueFromName("", "id")
            Debug.Print "Start", strLocalName, cls, vers, distName, id
        Case "p"
            inP = True
            pName = oAttributes.getValueFromName("", "name")
            Debug.Print "Start", strLocalName, pName
    End Select
End Sub

Private Sub IVBSAXContentHandler_endElement(strNamespaceURI As String, strLocalName As String, strQName As String)
    Select Case strLocalName
        Case "SampleObject"
            inSO = False
            cls = ""
            vers = ""
            distName = ""
            id = ""
        Case "p"
            pName = ""
            inP = False
    End Select
End Sub

Private Property Set IVBSAXContentHandler_documentLocator( _
                            ByVal RHS As MSXML2.IVBSAXLocator)
End Property

Private Sub IVBSAXContentHandler_startDocument()
End Sub

Private Sub IVBSAXContentHandler_endDocument()
End Sub

Private Sub IVBSAXContentHandler_endPrefixMapping(strPrefix As String)
End Sub

Private Sub IVBSAXContentHandler_ignorableWhitespace(strChars As String)
End Sub

Private Sub IVBSAXContentHandler_processingInstruction(strTarget As String, strData As String)
End Sub

Private Sub IVBSAXContentHandler_skippedEntity(strName As String)
End Sub

Private Sub IVBSAXContentHandler_startPrefixMapping(strPrefix As String, strURI As String)
End Sub

Answer 2

我尝试在“IVBSAXContentHandler_StartElement”中输入一个新的 Sub（在每种选择情况下），但它会产生错误。

Public Sub Ins_2G1(strLocalName As String, cls As String, vers As String, distName As String, id As String)
    Dim DNameArr() As String
    Dim insertcol As String
    Dim insertval As String

    DNameArr() = Split(distName, "/")
    colvalues(0) = distName
    colvalues(1) = DNameArr(1)
    colvalues(2) = DNameArr(2)
    colvalues(3) = DNameArr(3)

    'Converting Generated Parameter Name Array in to String
    insertcol = ""
    For i = LBound(colnames) To UBound(colnames)
        insertcol = insertcol + CStr(colnames(i))
        If i < UBound(colnames) Then
            insertcol = insertcol + ","
        End If
    Next

    'Converting Generated Value Array in to String
    insertval = "'"
    For i = LBound(colvalues) To UBound(colvalues) + 3
        insertval = insertval + CStr(colvalues(i))
        If i < UBound(colvalues) Then
            insertval = insertval + "','"
        End If
    Next
    insertval = insertval + "'"

    'Inserting Record in to POC table
    strSql = "INSERT INTO [" & cls & "] (" & insertcol & ") VALUES (" & insertval & ");"
    db.Execute strSql


End Sub