在 MainForm 上的 SubForm 中使用 Date 过滤值答案

【问题标题】：Using a Date filtered value from a SubForm on the MainForm在 MainForm 上的 SubForm 中使用 Date 过滤值
【发布时间】：2021-05-31 03:57:38
【问题描述】：

我正在尝试获取已过滤的 SubForm 的最后一个条目，并将该单个值放在 MainForm 上。该条目也应该在 Date_0 和 Date_1 之间，尽管并非总是指定 Date_1（在这种情况下，只需从 SubForm 中获取最后一个条目）。所以你得到了一个更形象化的想法（这是对真实 Form 的简化）：

主窗体：

Date_0	Date_1	ValueToGet
2020/12/23	2021/02/27	Value from Subform

子表单：

Dates	Values
2020/12/20	1200
2020/12/23	1189
2021/01/25	1173
2021/02/20	1165
2021/03/12	1333

在此示例中，从子表单收集的值将是第四个条目（在 Date_0 和 Date_1 之间，以及该日期范围内的最后一个条目）。然后将该值作为表单加载存储在 MainForm 中的 txtBox 中。我知道解决方案可能是在 txtBox 上设置 SQL 过滤器，但我不知道该怎么做。任何帮助将不胜感激。提前致谢！

【问题讨论】：

删除了我的答案，因为我没有完全阅读问题，然后我测试了我的建议，并且聚合函数不适用于动态参数的文本框。这很可能需要域聚合函数或 VBA 自定义函数。仍在探索中。
您可能需要一些 VBA 编码并通过单击命令按钮来调用代码。

标签： sql vba ms-access subform

【解决方案1】：

你可以试试下面的子-

Private Sub cmdGetResult_Click()
Dim strFilter As String
Dim rs As DAO.Recordset
    
    Me.Refresh
    
    strFilter = "[Dates] BETWEEN #" & Me.Date_0 & "# AND #" & Me.Date_1 & "#"

    Forms![Form1]![subformTest].Form.Filter = strFilter
    Forms![Form1]![subformTest].Form.FilterOn = True
    
    Set rs = Me.subformTest.Form.RecordsetClone
    
    rs.MoveLast
    Me.txtValueToGet = rs!values
    
    Forms![Form1]![subformTest].Form.FilterOn = False
    Set rs = Nothing
    
End Sub

【讨论】：

谢谢。该按钮适用于我的示例（在 Null 的情况下使用 date_1 上的 NZ() 函数），但问题是，子表单已经设置了一个过滤器，并且在修改它时记录会变得混乱。我可以以某种方式直接在 DAO.Recordset 上应用过滤器而不过滤实际的 subForm 的记录集吗？

【解决方案2】：

OnLoad 事件可能为时过早，但这样的事情应该可以工作：

Private Sub Form_Current()

    Dim Records As DAO.Recordset
    Dim Value   As Long
    Dim Found   As Boolean

    Set Records = Me!NameOfYourSubformControl.Form.RecordsetClone
    If Records.RecordCount > 0 Then
        Records.FindFirst "[Dates] >= #" & Format(Me!Date_0.Value, "yyyy\/mm\/dd") & "#"
        If Records.NoMatch Then
            ' No dates to look up.
        Else
            If IsNull(Me!Date_1.Value) Then
                Records.MoveLast
                Value = Records!Values.Value
                Found = True
            Else
                While Records.EOF = False And Found = False
                    If Records!Dates.Value >= Me!Date_1.Value Then
                        Value = Records!Values.Value
                        Found = True
                    End If
                    Records.MoveNext
                Wend
            End If
        End If
    End If
    Records.Close

    If Found = True Then
        Me!ValueToGet.Value = Value
    End If

End Sub

【讨论】：

谢谢。运行代码时，在 Date_1 为 Null 的情况下，我收到以下错误：Value = Records!Values.Value <Item not found in the collection.> 知道为什么会这样吗？
这很奇怪。应该有记录，但请仔细检查所有内容。