使用 vba 创建/复制（所有帐户上的此规则）outlook

Question

有没有办法使用vba代码将一个帐户的outlook规则复制到另一个帐户。我在互联网上进行了研究，但没有发现任何与我的问题相关的东西，请帮助我。参考任何链接。我不是 vba 专家。我会非常感谢你。

Answer 1

见Import or export a set of rules。

您可以通过编程方式创建规则。 Rules 类的Create 方法创建一个Rule 对象，其名称由Name 指定，规则类型由RuleType 指定。添加规则的RuleType 参数确定可以与Rule 对象关联的有效规则操作、规则条件和规则异常条件。集合中添加规则时，新规则的Rule.ExecutionOrder为1。集合中其他规则的ExecutionOrder加1。

 Sub CreateRule() 
   Dim colRules As Outlook.Rules 
   Dim oRule As Outlook.Rule 
   Dim colRuleActions As Outlook.RuleActions 
   Dim oMoveRuleAction As Outlook.MoveOrCopyRuleAction 
   Dim oFromCondition As Outlook.ToOrFromRuleCondition 
   Dim oExceptSubject As Outlook.TextRuleCondition 
   Dim oInbox As Outlook.Folder 
   Dim oMoveTarget As Outlook.Folder 
   'Specify target folder for rule move action 
   Set oInbox = Application.Session.GetDefaultFolder(olFolderInbox) 
   'Assume that target folder already exists 
   Set oMoveTarget = oInbox.Folders("Dan") 
   'Get Rules from Session.DefaultStore object 
   Set colRules = Application.Session.DefaultStore.GetRules() 
   'Create the rule by adding a Receive Rule to Rules collection 
   Set oRule = colRules.Create("Eugene's rule", olRuleReceive) 
   'Specify the condition in a ToOrFromRuleCondition object 
   'Condition is if the message is sent by "DanWilson" 
   Set oFromCondition = oRule.Conditions.From 
   With oFromCondition 
    .Enabled = True 
    .Recipients.Add ("Eugene Astafiev") 
    .Recipients.ResolveAll 
   End With 

   'Specify the action in a MoveOrCopyRuleAction object 
   'Action is to move the message to the target folder 
   Set oMoveRuleAction = oRule.Actions.MoveToFolder 
   With oMoveRuleAction 
    .Enabled = True 
    .Folder = oMoveTarget 
   End With 

   'Specify the exception condition for the subject in a TextRuleCondition object 
   'Exception condition is if the subject contains "fun" or "chat" 
   Set oExceptSubject = _ 
   oRule.Exceptions.Subject 
   With oExceptSubject 
    .Enabled = True 
    .Text = Array("fun", "chat") 
   End With 

   'Update the server and display progress dialog 
   colRules.Save 
 End Sub