如何使用 VBA 将 Microsoft Word 内容控制字段数据写入文本文件？

Question

我有一个看似微不足道的 VBA 任务。但是，我通常不使用 VBA，而且几乎从不在 Microsoft Word 的上下文中使用。我有一个利用内容控制字段（以及一些 ActiveX 单选按钮）的 Word 表单，需要通过将时间戳和完整的表单条目打印到逗号分隔文件来对其进行测试。当我运行以下代码时：

Sub WriteToText()
Dim DataFile As String
Dim StrData As String
Dim CCtrl As ContentControl
Dim bControl_Exists As Boolean

DataFile = "C:\Users\Annabanana\Documents\Data.txt"
StrData = "": Open DataFile For Append As #1
StrData = Format(Now, "DD-MMM-YYYY hh:mm:ss")

With Application.ActiveDocument
    bControl_Exists = .Saved
    For Each CCtrl In ThisDocument.ContentControls
        With CCtrl
            Select Case .Type
                Case Is = wdContentControlCheckBox
                    StrData = StrData & "," & .Checked
                Case wdContentControlDate, wdContentControlDropdownList, wdContentControlComboBox, wdContentControlText
                    StrData = StrData & "," & .Range.Text
                Case Else
            End Select
        End With
    Next
End With
Print #1, StrData: Close #1
End Sub

我得到了日期戳，但没有别的。理想情况下，我希望最终打印字段标签及其相应的值：

标签 1 值 1 标签 2 值 2 标签 3 值 3 ......

最终所有这些都会打印到数据库中，但此时我只想能够看到数据是如何从表单中出来的，以及在加载之前我需要如何对其进行转换。任何意见是极大的赞赏。谢谢。

Answer 1

从本质上讲，您的问题归结为滥用 ThisDocument。试试：

Sub GetCCtrlData()
Dim CCtrl As ContentControl, StrData As String, DataFile As String
StrData = Format(Now, "DD-MMM-YYYY hh:mm:ss")
DataFile = "C:\Users\" & Environ("UserName") & "\Documents\Data.txt"
For Each CCtrl In ActiveDocument.ContentControls
  With CCtrl
    StrData = StrData & vbTab & .Title & "|" & .Tag & ": "
    Select Case .Type
      Case Is = wdContentControlCheckBox
        StrData = StrData & .Checked
      Case wdContentControlDate, wdContentControlDropdownList, wdContentControlRichText, wdContentControlText
        StrData = StrData & .Range.Text
      Case Else
    End Select
  End With
Next
Open DataFile For Append As #1: Print #1, StrData: Close #1
End Sub

上面的代码还导出了内容控件的标题和标签，使用制表符分隔符而不是逗号。使用制表符分隔符允许数据中可能存在逗号。

我想，在某个阶段，您会想要处理多个文档。为此，请参阅：http://www.vbaexpress.com/forum/showthread.php?40406-Extracting-Word-form-Data-and-exporting-to-Excel-spreadsheet&p=257696&viewfull=1#post257696。虽然那里的代码将数据提取到 Excel 工作簿，但基本原理是相同的。