VBA unprotect-blank进入和退出处理[重复]

Question

下面的代码取消保护工作簿中的所有工作表，并且只提示输入一次密码。

我想要实现的是：

如果用户在密码输入窗口按“取消”，子程序退出。 如果用户在没有输入任何内容的情况下按“ok”，它的行为应该与输入错误密码相同，即转到错误弹出窗口。

问题在于按“确定”或“取消”时，它的行为与上述不同，相反，在这两种情况下，它都会再显示 3 次默认密码提示，每张纸 1 次。

我正在努力完善 if/then 逻辑，并且已经多次交换了一些东西，几乎到了那里，但从未完全做到。

Sub UnprotectAllSheets()
    Dim ws As Worksheet
    Dim pass As String
    
    If ActiveSheet.ProtectContents = False Then
        MsgBox "Already Unprotected" 
        Exit Sub
    Else

        pass = InputBox("Password?")
        On Error GoTo Popup:
        
        For Each ws In ThisWorkbook.Worksheets
            ws.Unprotect pass
        Next ws
        
        If ActiveSheet.ProtectContents = False Then
            MsgBox "Sheets now Unprotected"
            
        ElseIf StrPtr(pass) = "" Then  'if press OK on blank entry
            MsgBox "Incorrect Password", vbCritical, "Admin"
            
        ElseIf pass = 0 Then 'if press CANCEL
            Exit Sub
        End If
    End If
Popup:
    If err.Number = 1004 Then
        MsgBox "Incorrect Password", vbCritical, "Admin"
    End If
End Sub

Answer 1

InputBox 在按Cancel、输入空字符串或按窗口角 x 的情况下的行为类似，就String 返回而言。

下一个 sub 提供了将上述情况分开的可能性：

Sub testInputBox()
   Dim pass
    pass = InputBox("Password?")
    'standard behavior without checking the result:
    MsgBox "Pass is " & pass 'it will be an empty string in case of Cancel, empty string, pressing window corner X
    If StrPtr(pass) = 0 Then
        MsgBox ("Cancel pressed...") 'the same message if window corner `X` is pressed
    ElseIf pass = vbNullString Then
        MsgBox ("Empty string..")    'OK for an empty string
    Else
        MsgBox ("You entered " & pass)
    End If
End Sub

如果使用上述识别方式，则无需错误处理。

我应该修改你的代码以这样的方式行动：

Sub UnprotectAllSheets()
    Dim ws As Worksheet, pass As String, myPass As String, i As Long
    
        myPass = "1234"
TryAgain:
        pass = InputBox("Password?")
        If StrPtr(pass) = 0 Then Exit Sub 'for Cancel and window corner 'X' pressed
        If pass = vbNullString Then MsgBox "You did  not enter any password!", vbCritical, "Admin": Exit Sub
        If pass <> myPass Then
            
            MsgBox "Incorrect Password" & vbCrLf & _
                       IIf(i < 3, "Please, try again!", "We stop here..."), vbCritical, "Admin"
             If i >= 3 Then Exit Sub
            i = i + 1
           
            GoTo TryAgain
        End If
        For Each ws In ThisWorkbook.Worksheets
           If ws.ProtectContents = True Then
                ws.Unprotect pass
           End If
        Next ws
End Sub