VBA 和正则表达式 - 识别存储为文本的数字

Question

我有一些看起来像这样的数据（超过 400 列）：

year	ID	fake_num1	fake_num2	text1
2019	11	36 000	10'000	text, 1
2020	12	-1 275	1 000,00	text 2

列 fake_num1 和 fake_num2 存储为文本。我想要实现的是

1. 识别那些假数字列
2. 使用 for 循环清理数据（例如，删除空格、列、用点替换逗号）

我在第 1 步需要一些帮助。我必须识别列 fake_num1 和 fake_num2，同时避免使用 text1 等列。我正在考虑使用正则表达式，但也许还有另一种解决方案。

我在这里使用了部分代码：SO regexp，但是我不确定如何从那里继续。

Dim strPattern as String: strPattern = "^[0-9]$"

会找到任何以数字开头和结尾的东西，并且只有数字（如果我的理解是正确的）。管理上表所列案例的最佳方法是什么？

Answer 1

请尝试下一个代码，它将“假数字列”视为替换必要字符使字符串变为数字的列：

Sub testMakeNumbers()
 Dim sh As Worksheet, lastR As Long, lastCol As Long, i As Long, rngCol As Range
 
 Set sh = ActiveSheet 'you can use here the necessary sheet
 lastR = sh.Range("A" & sh.rows.Count).End(xlUp).row
 lastCol = sh.cells(1, Columns.Count).End(xlToLeft).Column
 
 'determine the problematic columns:
 For i = 1 To lastCol
    If Not IsNumeric(sh.cells(2, i).Value) And _
            IsNumeric(Replace(Replace(Replace(sh.cells(2, i).Value, " ", ""), "'", ""), ",", ".")) Then
        If rngCol Is Nothing Then
            Set rngCol = sh.cells(2, i)
        Else
            Set rngCol = Union(rngCol, sh.cells(2, i))
        End If
    End If
 Next
 'replace the characters making the string as number:
 With Intersect(rngCol.EntireColumn, sh.Range("A2", sh.cells(lastR, lastCol)))
       .Replace ",", "."
       .Replace Chr(160), ""
       .Replace " ", ""
       .Replace "'", ""
  End With
End Sub