VBA excel参考用户表单作为变量来获取数据

Question

我有几天时间来解决这个问题。我正在使用 excel VBA 填写 Word Doc。 我有多个包含文本框、组合框等的用户窗体，为了保持代码小而不是一遍又一遍地创建相同的模块，我只需要更改 FormName

此代码正在填写 Word Doc

wDoc.SelectContentControlsByTitle("#MonthBox").Item(1).Range.Text = Request_Form_1.MonthBox.Value

但我想使用变量来引用模块中的用户窗体，但我得到所有类型的错误

Dim FormName As String
FormName = "Request_Form_1"
wDoc.SelectContentControlsByTitle("#MonthBox").Item(1).Range.Text = FormName.MonthBox.Value

亲切的问候

感谢您的支持 我尝试过但不起作用

1. 尝试过的用户表单（NumeForma） MsgBox UserForms(NumeForma).LunaBox.Value 表单可见但我得到 error 13 type mismatch
2. 尝试插入包含ShowAnyForm() 调用MsgBox ShowAnyForm(NumeForma).LunaBox.Value 错误“预期函数或变量”的模块
3. 模块 ShowAnyForm() 从 Sub 更改为 Function 使用 MsgBox ShowAnyForm(NumeForma).LunaBox.Value 需要错误 424 对象

Answer 1

点前面或后面的所有内容（如FormName.）都不能（容易）被变量替换，因为它是一个对象或成员（但你可以CallByName它！）。

变量必须作为实参传递给参数，但由于集合可以访问许多对象，这就是我们通常采用的方式。

已加载用户表单可以在 UserForms 集合中找到。但它们只能通过它们的项目索引（0 到 UserForms.Count() -1）而不是它们的名字来访问。所以你需要某事。喜欢：

'code by http://www.cpearson.com/Excel/showanyform.htm
For Each Obj In VBA.UserForms
     If StrComp(FormName, Obj.Name, vbTextCompare) = 0 Then ' If Obj.Name matches FormName loop is exited and Obj contains the UserForm reference of FormName.
         Exit For
     End If
Next Obj

获取加载的用户表单引用。 示例代码可在Show Any Form 获得。

您的代码应如下所示：

wDoc.SelectContentControlsByTitle("#MonthBox").Item(1).Range.Text = ControlValueByName(FormName:=FormName, ControlName:="MonthBox", _
        ProcName:="Value", CallType:=vbGet)

我添加了一个函数来返回给定 FormName 的 UserForm 引用：

'Code inspired by http://www.cpearson.com/Excel/showanyform.htm
Public Function UserFormByName(ByVal FormName As String) As UserForm
Dim Obj As Variant
For Each Obj In VBA.UserForms
    If StrComp(FormName, Obj.Name, vbTextCompare) = 0 Then
        Exit For
    End If
Next Obj
If Obj Is Nothing Then ' UserForm not loaded
    Err.Clear
    Set Obj = VBA.UserForms.Add(FormName)
    If Err.Number <> 0 Then
        MsgBox "Error Calling Form: " & FormName
        Exit Function
    End If
End If
Set UserFormByName = Obj
End Function

现在你可以使用了：

wDoc.SelectContentControlsByTitle("#MonthBox").Item(1).Range.Text = UserFormByName(FormName).MonthBox.Value

如果您从用户窗体调用方法，事情会变得更容易，因为您可以简单地将引用传递给它。见 OP 的answer

在表格上：

Private Sub InregistreazaButtonActive2_Click()
    ToWord Me
End Sub

在模块中：

Sub ToWord(ByRef Caller As UserForm)
    MsgBox Caller.AnBox.Value
End Sub

您可以传递包含表单引用的列表框引用，而不是表单引用，因为它是表单的子对象，所以表单是ListBox.Parent。

Private Sub InregistreazaButtonActive2_Click()
    ToWord Me.AnBox
End Sub

Sub ToWord(ByRef CallerListBox As ListBox)
    MsgBox CallerListBox.Value
    Debug.Print CallerListBox.Parent.Name ' shows form name of listbox 
End Sub

通过传递引用，您不必担心多个实例（名称相同），因为每个实例都有自己的引用。

Answer 2

首先我想说谢谢@ComputerVersteher 二会粘贴孔代码

1. 在 excel 工作表中我有一个形状，点击会调用表单

Sub Start_Cerere_De_Autentificare_1_Click()
    Cerere_De_Autentificare_2.Show False
End Sub

1. 在表单上我有 3 个文本框（ZiBox、LunaBox、AnBox）

Public Sub UserForm_Activate()
     ZiBox = Day(Date)
     LunaBox = Month(Date)
     AnBox = Year(Date)
End Sub
Private Sub InregistreazaButtonActive2_Click()
    Call ToWord_CerereDeAutentificare2
End Sub

1. 按下注册按钮时会调用

Sub ToWord_CerereDeAutentificare2()

    Dim NumeForma As String
    NumeForma = "Cerere_De_Autentificare_2"

    Dim AllName As Object
    Set AllName = UserFormByName(NumeForma)

    MsgBox AllName.AnBox.Value
End Sub

4. 这将调用您的代码，该代码将返回表单名称，最后可以通过一行轻松访问存储在文本框中的值 MsgBox AllName.AnBox.Value

Public Function UserFormByName(FormName As String) As UserForm
Dim Obj As Variant
For Each Obj In VBA.UserForms
    If StrComp(FormName, Obj.Name, vbTextCompare) = 0 Then
        Exit For
    End If
Next Obj
If Obj Is Nothing Then ' UserForm not loaded
    Err.Clear
    Set Obj = VBA.UserForms.Add(FormName)
    If Err.Number <> 0 Then
        MsgBox "Error Calling Form: " & FormName
        Exit Function
    End If
End If
Set UserFormByName = Obj
End Function

再次感谢您