检测范围是否为空

Question

我想检查 Excel 中的某个区域是否为空。

如何用 VBA 代码编写：

If Range("A38":"P38") is empty

Answer 1

从我得到的 cmets 中找到了解决方案。

Sub TestIsEmpty()
    If WorksheetFunction.CountA(Range("A38:P38")) = 0 Then
        MsgBox "Empty"
    Else
        MsgBox "Not Empty"
    End If
End Sub

Answer 2

如果您发现自己无法使用CountA，那么首先将您的范围存储为数组并循环数组数据要比循环范围/单元格数据快得多。

Function IsRangeEmpty(ByVal rng As Range) As Boolean
    'Converts a range to an array and returns true if a value is found in said array
    
    Dim area As Range
    For Each area In rng.Areas
        
        If area.Cells.Count > 1 Then
        
            'save range as array
            Dim arr As Variant
            arr = area.value
            
            'loop through array
            Dim cel As Variant
            For Each cel In arr
            
                'if cell is not empty then
                If Len(Trim(cel)) > 0 Then
                    IsRangeEmpty = False
                    Exit Function
                End If

            Next cel
            
        Else    'cannot loop on array with one value
            
            'if cell is not empty then
            If Len(Trim(area.Value2)) > 0 Then
                IsRangeEmpty = False
                Exit Function
            End If
            
        End If

    Next area

    IsRangeEmpty = True

End Function

---

使用示例：

Sub Test()
    Debug.Print IsRangeEmpty(Range("A38:P38"))
End Sub

如果Range("A38:P38") 为空，它将在即时窗口中打印True；否则它会打印False。

Answer 3

如果变量未初始化或显式设置为 Empty，则 IsEmpty 返回 True；否则，它返回 False。如果表达式包含多个变量，则始终返回 False。 IsEmpty 仅返回对变体有意义的信息。 (https://msdn.microsoft.com/en-us/library/office/gg264227.aspx)。因此，您必须分别检查范围内的每个单元格：

    Dim thisColumn as Byte, thisRow as Byte

    For thisColumn = 1 To 5
        For ThisRow = 1 To 6
             If IsEmpty(Cells(thisRow, thisColumn)) = False Then
                 GoTo RangeIsNotEmpty
             End If
        Next thisRow
    Next thisColumn
    ...........
    RangeIsNotEmpty: 

当然，这里的代码比使用 CountA 函数计算非空单元格的解决方案要多，但是如果找到至少一个非空单元格，GoTo 可以中断循环，并且可以更快地执行代码，尤其是在范围很大并且需要检测的情况下这个案例。此外，与不是 VBA 函数的 Excel CountA 函数相比，这段代码对我来说更容易理解它在做什么。

Answer 4

Dim M As Range

    Set M = Selection

If application.CountIf(M, "<>0") < 2 Then
    MsgBox "Nothing selected, please select first BOM or Next BOM"
Else

'Your code here

End If

根据我刚刚了解到的经验，你可以做到：

If Selection.Rows.Count < 2 
Then End If`

稍后提供说明（现在我正在工作）

Answer 5

Dim cel As Range, hasNoData As Boolean

    hasNoData = True
    For Each cel In Selection
        hasNoData = hasNoData And IsEmpty(cel)
    Next

如果Selection 中没有单元格包含任何数据，这将返回True。对于特定范围，只需将 RANGE(...) 替换为 Selection。

Answer 6

另一种可能的解决方案。计算空单元格并从单元格总数中减去该值

Sub Emptys()

Dim r As range
Dim totalCells As Integer

'My range To check'
Set r = ActiveSheet.range("A1:B5")

'Check for filled cells'
totalCells = r.Count- WorksheetFunction.CountBlank(r)


If totalCells = 0 Then
    MsgBox "Range is empty"
Else
    MsgBox "Range is not empty"
End If

End Sub

Answer 7

这只是对@TomM'sanswer/的一个小补充 如果您选择的单元格为空

Public Function CheckIfSelectionIsEmpty() As Boolean
   Dim emptySelection As Boolean:emptySelection=True
   Dim cell As Range
   For Each cell In Selection
       emptySelection = emptySelection And isEmpty(cell)
       If emptySelection = False Then
          Exit For
       End If
   Next
   CheckIfSelectionIsEmpty = emptySelection
End Function

Answer 8

恕我直言，这一行效果更好：

Application.Evaluate("SUMPRODUCT(--(E10:E14<>""""))=0")

在这种情况下，它会评估范围 E10:E14 是否为空。