Excel 将单元格（工作表 A）中的子字符串替换为“查找”（工作表 B）中的相应字符串

Question

如何在 MS Excel 15.4 中执行此操作

我想将A列处理成B列

Column A                  | Column B
----------------------------------------------------------------------
one, 1, two, 2, three, 3  | one apple, two bananas, three strawberries
one, 1, four, 4           | one apple, four oranges
.......................
... many other rows ...
.......................
two, 2, four, 4, three, 3 | two bananas, four oranges, three strawberries    

A 列 可以在查找表中有 n 个匹配的子字符串。

我有另一张表（查找表），其中包含将 A 列 中的文本替换为

的内容

Match col | Replace col
----------------------------
one, 1    | one apple
two, 2    | two bananas
three, 3  | three strawberries
four, 4   | four oranges
... and many more ...

我想用查找表的 替换 col 值替换 A 列 中的所有子字符串

看起来我可以将VLOOKUP 与SUBSTITUTE 结合起来，但我正在努力解决它

Answer 1

我有一个相当笨拙的解决方案，但如果您不介意采取一些额外的步骤，它会为您工作。 （不需要 VBA）。

使用您的原始数据，突出显示所有数据并使用逗号分隔符执行Text to Columns。将目的地设置为您喜欢的任何地方。我选择了它右边的列（所以，B2）：

所以现在你把它全部分开了。

我将VLOOKUP() 表放在“Sheet2”中：

回到 Sheet1，在 I2 中，我使用了这个公式：
=IFERROR(VLOOKUP(TRIM(B2)&", "&TRIM(C2),Sheet2!$A$1:$B$4,2,FALSE),"")

然后向右拖动。您将拥有一些可以隐藏/删除的空列，然后复制所有数据。

Answer 2

在单个单元格中进行；

=IFERROR(VLOOKUP(TRIM(SUBSTITUTE(MID(SUBSTITUTE($A1,",",REPT(" ",999)),(COLUMN(A:A)-1)*2*999+1,2*999),REPT(" ",999),",")),Sheet2!$A:$B,2,FALSE),"")

---

如果您订阅了 Office 365¹ excel，您可以使用此数组公式将其全部放在一个单元格中：

=TEXTJOIN(",",TRUE,IFERROR(LOOKUP(TRIM(SUBSTITUTE(MID(SUBSTITUTE($A1,",",REPT(" ",999)),(ROW(INDIRECT("1:" & INT((LEN($A1)-LEN(SUBSTITUTE($A1,",","")))/2)+1))-1)*2*999+1,2*999),REPT(" ",999),",")),Sheet2!A:A,Sheet2!B:B),""))

作为数组公式，退出编辑模式时必须使用 Ctrl-Shift-Enter 而不是 Enter 来确认。如果操作正确，Excel 会在公式周围加上{}。

需要注意的是，参考数据必须在查找列上排序：

---

_{¹ 如果您没有 Office 365 但想使用此公式，您可以将我的答案 HERE 中的代码放置在附加到的模块中，该代码将模仿 TEXTJOIN()工作表。然后使用上述公式}