将工作表的副本命名为原始工作表中单元格中的值

Question

此脚本循环通过文件路径并将所有工作簿组合到主工作簿中，并将每个工作簿划分为主文件中的工作表。

我有一行 ws.Name = activeworksheet.Range("B1").Value 将工作表命名为第一个工作簿的工作表 Sheet1 的副本，然后将每个工作表命名为 Sheet1(2)。

如何将其更改为要合并到主工作簿的工作簿单元格 B1 中的值？

脚本的其余部分：

Option Explicit

Sub CombineWorkbooks()

    Dim MainWB As Workbook
    Dim sDirPath As String
    Dim sFileName As String
    Dim sFilePath As String
    Dim wb As Workbook
    Dim ws As Worksheet

    sDirPath = "M:\New folder"

    sFileName = Dir(sDirPath & "\*.xlsx")

    Set MainWB = ThisWorkbook

    Do While Len(sFileName) > 0

        sFilePath = sDirPath & "\" & sFileName

        Set wb = Workbooks.Open(Filename:=sFilePath)

        For Each ws In wb.Sheets
            ws.Copy After:=MainWB.Sheets(MainWB.Sheets.Count)    
            ws.Name = activeworksheet.Range("B1").Value
        Next ws

        wb.Close SaveChanges:=False

        sFileName = Dir
    Loop
End Sub  

Answer 1

在Sheet 对象的.Copy() 方法之后，新创建的工作表变为活动，而ws 仍保留对原始工作表的引用 p>

所以像下面这样去

        For Each ws In wb.Sheets
            ws.Copy After:=MainWB.Sheets(MainWB.Sheets.Count)

            ActiveSheet.Name = ws.Range("B1").Value
        Next