如何在 PowerBI 中使用 DAX 创建动态子表

Question

我有这张桌子：

Order | Total  | FirstPayment | Months
1     | 1000   | 2021-01-01   | 2
2     | 600    | 2021-02-01   | 3

我需要用分期付款创建另一个表，如下所示：

Month      | Order  | Value
2021-01-01 | 1      | 500
2021-02-01 | 1      | 500
2021-02-01 | 2      | 200
2021-03-01 | 2      | 200
2021-04-01 | 2      | 200

所以，我想为每个月的付款创建一个包含一行的子表。

拜托，你能帮忙吗？

Answer 1

根据我的评论，我实际上会这样做：

创建涵盖两个范围之间所有日期的日期表。您实际上可以过滤它以仅包含相关日期以获得更好的性能，但我没有打扰（这是一个表格公式）：

Payments = CALENDAR(MIN(Orders[FirstPayment]), MAXX(Orders, EDATE(Orders[FirstPayment], Orders[Months])))

创建一个可以显示相关日期的适当值的度量：

Payment amount = 
SUMX (
    Payments,
    VAR d =
        DAY ( Payments[Date] )
    RETURN
        SUMX (
            FILTER (
                Orders,
                DAY ( Orders[FirstPayment] )
                    == d
                        && Payments[Date] <= EDATE ( Orders[FirstPayment], Orders[Months] -1 )
                        && Payments[Date] >= Orders[FirstPayment]
            ),
            [Total] / [Months]
        )
)

结果 - 基于 Orders 表中的 Order 和 Payments 表中的 Date：

编辑

当然，也可以按照你的要求去做。您必须结合这两个公式来创建这样的计算表（以下是您在选择新表时应用的表公式）：

Installments =
SELECTCOLUMNS (
    FILTER (
        CROSSJOIN (
            CALENDAR (
                MIN ( Orders[FirstPayment] ),
                MAXX ( Orders, EDATE ( Orders[FirstPayment], Orders[Months] ) )
            ),
            Orders
        ),
        [Date] >= [FirstPayment]
            && DAY ( [Date] ) = DAY ( [FirstPayment] )
            && [Date]
                <= EDATE ( [FirstPayment], [Months] - 1 )
    ),
    "Date", [Date],
    "Order", [Order],
    "Value", [Total] / [Months]
)