填充x86 MASM汇编语言后对数组进行排序

Question

谁能帮我解决这个问题，我是汇编语言的新手，有点坚持下一步该做什么。代码如下：

.data
evenStart    dword          11h
oddStart     dword          20h
darray       dword          15 dup (?)
.code
main PROC
    mov esi, OFFSET darray
    xor ecx, ecx
    
L1: 
    mov ebx, OFFSET evenStart
    test cl,1
    jz iseven
    mov ebx, OFFSET oddStart
    
iseven:
    mov eax, [ebx]
    inc dword ptr [ebx]
    mov dword ptr [esi + 4*ecx],eax
    inc ecx
    cmp ecx,15
    jb L1
    
    exit
main ENDP
END main

所以项目需要我填充未初始化的数组，我这样做了。但随后它也要求我对这个数组进行降序排序，然后将数组的中间元素放入 eax 寄存器并调用 DumpRegs。这是我陷入困境的部分。有关如何进行的任何帮助都会很棒。谢谢！

Answer 1

下一个冒泡排序使用嵌套循环。因为您的数组有 15 个元素，所以外部循环在其第一次迭代期间可以进行 14 次比较。对于外部循环的每次迭代，它必须少做 1 次比较，因为最小的元素已经冒泡到数组的末尾。

    mov ebx, 15-1      ; Outer loop iteration count
OuterLoop:
    mov esi, offset darray

    mov ecx, ebx       ; Inner loop iteration count
InnerLoop:
    lodsd
    mov edx, [esi]
    cmp eax, edx
    jge Skip
    mov [esi-4], edx   ; Swap these 2 elements
    mov [esi], eax
Skip:
    dec ecx
    jnz InnerLoop

    dec ebx
    jnz OuterLoop

未排序的数组： 11h, 20h, 12h, 21h, 13h, 22h, 14h, 23h, 15h, 24h, 16h, 25h, 17h, 26h, 18h

排序后的数组： 26h, 25h, 24h, 23h, 22h, 21h, 20h, 18h, 17h, 16h, 15h, 14h, 13h, 12h, 11h

在这个包含奇数个元素 (15) 的数组中，元素索引的范围从 0 到 14。在索引 7 处有一个真正的中间元素。