Access VBA中具有多个列标题的交叉表

Question

我有一个具有这种结构的表（“Spot”是存储项目的位置，“N”是该位置的项目数）。

Id | Spot1 | N1 | Spot2 | N2 | Spot3 | N3 |
1  |   A   | 2  |   B   | 2  |   C   | 1  |
2  |   B   | 2  |   C   | 1  |   D   | 2  |
3  |   A   | 2  |   C   | 1  |   D   | 5  |

我想对该表运行查询并创建如下表：

ID | A | B | C | D |
1  | 2 | 2 | 1 | _ |
2  | _ | 2 | 1 | 2 |
3  | 2 | _ | 1 | 5 |

在决定构建此查询的最佳策略时，我需要一些帮助。

我正在考虑创建几个具有不同列标题的交叉表查询，并以某种方式将这些交叉表合并在一起。

这是一个好方法还是有更有效的方法。我的示例只有 4 个不同的项目，但我的实际表有大约 20 个项目，因此最终表将有 20 列和超过 200 条记录。

Answer 1

我建议先拼接，然后交叉制表。我们可以使用包含您的源 ID、Spot 和 Amount 的中间三列表来执行此操作。以下代码是一种通用方法，它不假设源表中有多少列。它也不假设存在多少个点。它确实假设表 tmpTbl 已经存在。

Sub largeCrossTab()
    Dim rst As DAO.Recordset, rst2 As DAO.Recordset
    Set rst = CurrentDb.OpenRecordset("Table1")
    Dim fld As DAO.Field
    CurrentDb.Execute "DELETE FROM tmpTbl"
    For Each fld In rst.Fields
        If InStr(fld.Name, "Spot") > 0 Then
            CurrentDb.Execute "INSERT INTO tmpTbl(OrigID, Spot, Amount) " _
                & "SELECT ID, " & fld.Name & ", N" & Right(fld.Name, Len(fld.Name) - 4) _
                & " FROM Table1"
        End If
    Next
    Set rst2 = CurrentDb.OpenRecordset("TRANSFORM Nz(Sum(Amount), '_') " _
        & "SELECT OrigID " _
        & "FROM tmpTbl " _
        & "GROUP BY OrigID " _
        & "PIVOT Spot")

    ''' Do something with rst2 '''

    Set rst = Nothing
    Set rst2 = Nothing
    Set fld = Nothing
End Sub