在 Neo4j Cypher 的 RETURN 语句中使用 WITH 语句之前的 vars

Question

我从 Neo4j (v2.1.5) 开始，但遇到以下 Cypher 查询问题：

MATCH (actor:Person{name:"Tom Cruise"})-[role:ACTED_IN]->(movies)<-[r:ACTED_IN]-(coactors)
WITH  coactors, count(coactors) as TimesCoacted
RETURN coactors.name, avg(TimesCoacted)
ORDER BY avg(TimesCoacted) DESC

它基于 Neo4j 安装附带的迷你电影图。

一切正常，它显示了与汤姆克鲁斯在电影中合作的所有合作者以及他们合作了多少次，但问题出现在我想要的时候列出他们合作的电影。在 RETURN 语句中放置“电影”变量会引发以下错误：

movies not defined (line 3, column 9)
"RETURN  movies, coactors.name, avg(TimesCoacted)"
         ^

有什么方法可以在一个查询中完成吗？

Answer 1

尝试以下方法：

MATCH 
    (actor:Person{name:"Tom Cruise"})-[role:ACTED_IN]->(movies)<-[r:ACTED_IN]-(coactors)
WITH 
    coactors, 
    count(coactors) as TimesCoacted, 
    movies // You have declare "movies" here in order to use it later in the query
RETURN 
    movies, 
    coactors.name, 
    avg(TimesCoacted)
ORDER BY 
    avg(TimesCoacted) DESC

您在WITH-statement 中定义的内容是唯一可用于进一步处理的内容。在最初的问题中，movies 没有被带到下一部分（它不是WITH 的一部分），因此movies 不能在返回语句中使用。

编辑：从 OP 更新后，添加了以下内容。

另一个例子。如果您想计算演员在电影中合作的次数并列出电影名称。请尝试以下操作：

MATCH 
    (actor:Person {name:"Tom Cruise"})-[:ACTED_IN]->(movie)<-[:ACTED_IN]-(coactor:Person)
WITH
    actor,
    coactor,
    collect (distinct movie.title) as movieTitles
RETURN
    actor.name as actorName, 
    coactor.name as coactorName, 
    movieTitles, 
    size(movieTitles) as numberOfMovies

Answer 2

MATCH 
    (actor:Person{name:"Tom Cruise"})-[role:ACTED_IN]->(movies)<-[r:ACTED_IN]-(coactors)
WITH 
    coactors, 
    count(coactors) as TimesCoacted, 
    collect(DISTINCT movies.title) as movies // <=- this line was crucial! 
RETURN 
    movies, 
    coactors.name, 
    avg(TimesCoacted)
ORDER BY 
    avg(TimesCoacted) DESC