如何使用 TObjectList<T> 的 Contains、Remove 或 IndexOf 等方法

Question

我在使用TObjectList<T> 类的Contains、Remove 或IndexOf 等方法时遇到问题， 当 T 是自定义类型时，例如以下示例代码中的 TSocket。

我首先实现了一个自定义的TSocket 类型，并尝试在TObjectList<TSocket> 类型的列表中使用它，如下所示：

list := nil;
socket := nil;
try
  list := TObjectList<TSocket>.Create();
  socket := TSocket.Create(TIpAddress.Parse('127.0.0.1'),6857);

  // add new socket object with equal values to list
  list.Add(TSocket.Create(TIpAddress.Parse('127.0.0.1'),6857));

  // should return true but returns false
  if list.Contains(socket) then
    WriteLn('socket contained in list')
  else
    WriteLn('socket not contained in list');

  // should return number 0 but returns -1
  if list.IndexOf(socket) = 0 then
    WriteLn('socket contained in list')
  else
    WriteLn('socket not contained in list');

  // should remove item from list but items doesn't get removed
  list.Remove(socket);

finally
  list.Free();
  socket.Free();

我预计Contains、IndexOf 和Remove 使用TMyObject 的Equals 过程并覆盖此过程的实现。因此，我在我的 TSocket 类中添加了 Equals 的以下实现：

type
  TSocket = class
  strict private
    _ipAddress: TIpAddress;
    _port: integer;
  public
    constructor Create(ipAddress: TIpAddress; port: integer);
    function GetIpAddress: TIpAddress;
    function GetPort: integer;
    property IpAddress: TIpAddress read GetIpAddress;
    property Port: integer read GetPort;
    function Equals(other: TObject): boolean; overload; override;
    destructor Destroy; override;
  end;

implementation

constructor TSocket.Create(ipAddress: TIpAddress; port: integer);
begin
  inherited Create();
  _ipAddress := ipAddress;
  _port := port;
end;

function TSocket.Equals(other: TObject): boolean;
var
  otherSocket: TSocket;
begin
  if not (other is TSocket) then exit(false);
  otherSocket := other as TSocket;
  result:= (_ipAddress.Equals(otherSocket.IpAddress)) and (_port = otherSocket.Port)
end;

function TSocket.GetIpAddress: TIpAddress;
begin
  result := _ipAddress;
end;

function TSocket.GetPort: integer;
begin
  result := _port;
end;

destructor TSocket.Destroy;
begin
  _ipAddress.Free();
  inherited Destroy();
end;

使用此代码Contains 返回 false 但应为 true，IndexOf 返回 -1 但应为 0，Remove 不删除对象但应删除它。我预计这些方法会使用TSocket 的Equals 方法，但他们没有。阅读文档后，我发现TObjectList 的构造函数可以通过 IComparer 的实现来调用。因此我实现了一个TEqualityComparer<TSocket> 以使用我的Equals 方法。 不幸的是TObjectList的构造函数不支持IEqualityComparer接口，而是使用IComparer接口。

问题： 在 Delphi 中使用自定义类型时，如何使用 Contains、Remove 或 IndexOf 之类的方法？ 在其他编程语言（如 Java 或 C#）中，Equals 用于比较列表类型中的对象。 Delphi 使用什么机制来比较对象？

更新 感谢您提供全面的反馈。我已经适当地更新了我的问题和代码。我详细说明了我在运行代码时的期望，并添加了更多代码以使我的意图更加清晰。 @DavidHeffernan：实施确实是错误的。我向 TInterfacedObject 添加了继承，以了解有关引用计数的更多信息。我从代码中删除了 TInterfacedObject。

Answer 1

您的错误是您假设TObjectList<T> 使用Equals 函数来测试相等性。

默认情况下，TObjectList<T>，或更准确地说是TList<T>，使用TComparer<T>.Default 返回的比较器。对于TObjectList<TSocket>，默认比较器比较指针本身。由于您创建了 2 个不同的对象，因此指针不同。你得到的结果就是预期的结果。

如果您想覆盖该默认行为，您需要提供自己的比较器。这样做的方法是像这样通过构造函数传递它：

TObjectList<TSocket>.Create(TComparer<TSocket>.Construct(
    function (const L, R : TSocket) : Integer
    begin
      //Compare here.
    end)
   );

你的函数应该：

• 如果 L 小于 R，则返回小于 0 的值。（通常为 -1）
• 如果 L 大于 R，则返回大于 0 的值。（通常为 1）
• 两者的返回 0 相等。

如果出于某种原因，您只想检查是否相等，您可以在技术上这样做并在不相等时返回 -1 或 1 而无需进一步比较。也就是说，只要您不打算通过它对列表或 BinarySearch 进行排序。