使用 Visual Studio DNX 项目 (.xproj) 进行代码分析

Question

在“普通”Visual Studio 项目 (.csproj) 的属性中，可以说 Enable Code Analysis on Build（以前称为 FxCop）。

自从我开始使用新的 DNX 项目 (.xproj) 以来，我正在寻找类似的东西。我知道可能没有构建输出，所以旧方法可能不适合这个，但我很确定代码分析/FxCop 规则仍然适用。此外，应该有一些方法可以在新的“实际”项目文件 (project.json) 中注册自定义规则集 (.ruleset) 文件。

也许我忽略了基于 Roslyn 之类的更现代的东西？

Answer 1

在 ASP.NET 工具 GitHub 站点 here 上有一个问题。它目前不受支持，但有望很快实现。当从 xproj 切换回 csproj 时，代码分析将再次工作。

更新

xproj 现在支持StyleCop.Analyzers。

Answer 2

终于找到了一种解决方法，在他们（希望）用下一个版本的 .NET Core 和 Visual Studio 修复它之前，应该可以解决这个问题。诀窍是为经典的 .NET Framework 构建执行“旧的”FxCop，这是运行旧式代码分析所必需的。

库的 project.json 应该包含类似的内容：

{
  "frameworks": {
    "net46": {
      "buildOptions": {
        "define": [ "CODE_ANALYSIS" ]
      }
    },
    "netstandard1.3": {
      "dependencies": {
        "NETStandard.Library": "1.6.0"
      }
    }
  },

  "scripts": {
    "postcompile": "../../CodeAnalysis.cmd %compile:TargetFramework% %compile:Configuration% %compile:OutputFile% %compile:CompilerExitCode%"
  }
 }

“应用程序”的 project.json 应包含实际运行时：

{
  "scripts": {
    "postcompile": "../../CodeAnalysis.cmd %compile:TargetFramework% %compile:Configuration% %compile:OutputFile% %compile:CompilerExitCode% %compile:RuntimeOutputDir%"
  }
 }

因此，使用 postcompile 事件可以运行某种批处理脚本来执行经典的 FxCop（需要 Visual Studio！）。我目前正在使用包含三个文件的设置：

• 代码分析.cmd
• CodeAnalysis.ruleset
• CodeAnalysis.xml（字典）

批处理文件“支持”当前的 .NET Framework 4.6 版本，如下所示：

@echo off

if not [%4]==[0] (
  goto :eof
)

if not [%2]==[Release] (
  goto :eof
)

if [%1]==[net46] (
  set VERSION=v4.6
) else if [%1]==[net461] (
  set VERSION=v4.6.1
) else if [%1]==[net462] (
  set VERSION=v4.6.2
) else (
  goto :eof
)

if not [%5]==[] (
  set FILE=%5\%~nx3
) else (
  set FILE=%3
)

set PLATFORM=%ProgramFiles(x86)%\Reference Assemblies\Microsoft\Framework\.NETFramework\%VERSION%
set DIRECTORY=%ProgramFiles(x86)%\Reference Assemblies\Microsoft\Framework\.NETFramework\%VERSION%\Facades

set FXCOP=%VS140COMNTOOLS:Common7\Tools=Team Tools\Static Analysis Tools\FxCop%FxCopCmd.exe
set RULES=%VS140COMNTOOLS:Common7\Tools=Team Tools\Static Analysis Tools\FxCop%Rules

"%FXCOP%" /platform:"%PLATFORM%" /directory:"%DIRECTORY%" /rule:"-%RULES%" /ruleset:"=%~dp0CodeAnalysis.ruleset" /dictionary:"%~dp0CodeAnalysis.xml" /file:"%FILE%" /ignoregeneratedcode /console /culture:de-DE

它不像普通的内置东西那么方便，但是使用Visual Studio时FxCop的错误/警告出现在错误列表中 em>（有时需要进行第二次构建）。但它们不会导致构建失败（也许还有其他技巧……）。

CodeAnalysis.ruleset 示例：

<?xml version="1.0" encoding="utf-8"?>
<RuleSet Name="All Rules, except a few ones" ToolsVersion="14.0">
    <IncludeAll Action="Error" />
    <Rules AnalyzerId="Microsoft.Analyzers.ManagedCodeAnalysis" RuleNamespace="Microsoft.Rules.Managed">
        <!-- CLS compliant -->
        <Rule Id="CA1014" Action="None" />
        <!-- COM visibility -->
        <Rule Id="CA1017" Action="None" />
    </Rules>
</RuleSet>