如何在 xslt 中控制布尔渲染

Question

为了符合<boolean> spec of Xml-RPC 我需要将我的xs:boolean 从true|false 转换为1|0。

我使用 xsl:choose 解决了这个问题

<xsl:template match="Foo">
    <member>
        <name>Baz</name>
        <value>
            <boolean>
                <xsl:choose>
                    <xsl:when test=".='true'">1</xsl:when>
                    <xsl:otherwise>0</xsl:otherwise>
                </xsl:choose>
            </boolean>
        </value>
    </member>
</xsl:template>

但想知道在使用 xslt 1.0 转换时是否有一种更简单的方法来控制布尔值的呈现方式。

Answer 1

使用：

number(boolean(.))

根据标准 XPath 函数 number() 的定义，当分别在 {true(), false()} 上应用时，它会准确生成 {0, 1}

当心！如果你在 strings 上使用这种结构，结果将 'false' 和 'true' 都为 true，因为，对于字符串参数，boolean() is true if and only if its length is non-zero。

所以，如果你想转换字符串，而不是布尔值，那么使用这个表达式：

number(not(. = 'false'))

以下是基于 XSLT 的验证：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="text()">
  <xsl:value-of select="number(not(. = 'false'))"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
 <x>true</x>
 <y>false</y>
</t>

产生想要的正确结果：

<t>
   <x>1</x>
   <y>0</y>
</t>