匹配 xa?b?c? 的正则表达式但不仅仅是 x

Question

我正在尝试编写一个匹配 xa?b?c? 的正则表达式？但不是 x。实际上，“x”、“a”、“b”和“c”不是单个字符，它们是中等复杂的子表达式，所以我试图避免类似 x(abc|ab|ac|bc |a|b|c)。有没有一种简单的方法可以在正则表达式中匹配“a、b 和 c 中的至少一个”，还是我不走运？

Answer 1

如果你绝对必须不重复a、b或c，那么这是最短、最简单的正则表达式——假设x代表一个固定长度的表达式，或者您正在使用的实现支持可变长度的实现。它使用否定的look-behind，例如，Perl 将死于可变长度的look-behind。

基本上就是你所说的，改写一下：

/(x)a?b?c?(?<!x)/;

它是这样说的：我想匹配 xa?b?c?但是当我考虑它时，我不希望最后一个表达式是 x。

此外，如果 a、b 或 c 的匹配以 x 结尾，它将不起作用。 （帽子提示：tchrist）

Answer 2

这个怎么样：

x(?:a())?(?:b())?(?:c())?(\1|\2|\3)

如果a、b 或c 匹配，则a、b 和c 之后的空捕获组将始终匹配（空字符串）。

(\1|\2|\3) 部分只有在至少有一个前面的组参与匹配时才会匹配。所以如果你只有x，那么正则表达式就会失败。

正则表达式的每个部分都将被评估一次。

当然，如果x、a、b 和c 是包含捕获组本身的更复杂的子表达式，则您必须相应地调整反向引用的数量*。

由于这个正则表达式看起来有点奇怪，这里是详细的版本：

x          # Match x
(?:a())?   # Try to match a. If this succeeds, \1 will contain an empty string.
(?:b())?   # Same with b and \2.
(?:c())?   # Same with c and \3.
(\1|\2|\3) # Now try to match the content of one of the backreferences. 
           # This works if one of the empty parentheses participated in the match.
           # If so, the backref contains an empty string which always matches. 
           # Bingo!

您可能需要用锚点（^ 和 $）围绕它，除非您不介意它在字符串 cxba 等中匹配 xb。

例如，在 Python 中：

>>> r=re.compile(r"x(?:a())?(?:b())?(?:c())?(\1|\2|\3)$")
>>> for test in ("x", "xa", "xabc", "xba"):
...     m = r.match(test)
...     if m:
...         print("{} --> {}".format(test, m.group(0)))
...     else:
...         print("{} --> no match".format(test))
...
x --> no match
xa --> xa
xabc --> xabc
xba --> no match

---

*或者，如果你的正则表达式知道命名的捕获组，你可以使用它们，例如

x(?:a(?P<a>))?(?:b(?P<b>))?(?:c(?P<c>))?((?P=a)|(?P=b)|(?P=c))

在 Python/PCRE 中。在 .NET（可能还有其他风格）中，拥有多个使用相同名称的捕获组甚至是合法的，这使得另一种简化成为可能：

x(?:a(?<m>))?(?:b(?<m>))?(?:c(?<m>))?\k<m>

Answer 3

这是最短的版本：

(a)?(b)?(c)?(?(1)|(?(2)|(?(3)|(*FAIL))))

如果您需要在单独的组中保持比赛，请写下：

((a)?(b)?(c)?)(?(2)|(?(3)|(?(4)|(*FAIL))))

但如果 a、b 或 c 包含捕获组，这并不是很可靠。所以改为这样写：

(?<A>a)?(?<B>b)?(?<C>c)?(?(<A>)|(?(<B>)|(?(<C>)|(*FAIL))))

如果整场比赛都需要一个小组，请写下：

(?<M>(?<A>a)?(?<B>b)?(?<C>c)?(?(<A>)|(?(<B>)|(?(<C>)|(*FAIL)))))

如果你像我一样更喜欢多字母标识符，并且认为这种事情在不处于 /x 模式的情况下很疯狂，请写下：

(?x)
(?<Whole_Match>
    (?<Group_A> a) ?
    (?<Group_B> b) ?  
    (?<Group_C> c) ?

    (?(<Group_A>)           # Succeed 
      | (?(<Group_B>)       # Succeed
          | (?(<Group_C>)   # Succeed
              |             (*FAIL)
            )
        )
    )
 )

这里有完整的测试程序来证明这些都有效：

#!/usr/bin/perl
use 5.010_000;

my @pats = (
    qr/(a)?(b)?(c)?(?(1)|(?(2)|(?(3)|(*FAIL))))/,
    qr/((a)?(b)?(c)?)(?(2)|(?(3)|(?(4)|(*FAIL))))/,
    qr/(?<A>a)?(?<B>b)?(?<C>c)?(?(<A>)|(?(<B>)|(?(<C>)|(*FAIL))))/,
    qr/(?<M>(?<A>a)?(?<B>b)?(?<C>c)?(?(<A>)|(?(<B>)|(?(<C>)|(*FAIL)))))/,
    qr{
        (?<Whole_Match>

            (?<Group_A> a) ?
            (?<Group_B> b) ?
            (?<Group_C> c) ?

            (?(<Group_A>)               # Succeed
              | (?(<Group_B>)           # Succeed
                  | (?(<Group_C>)       # Succeed
                      |                 (*FAIL)
                    )
                )
            )

        )
    }x,
);

for my $pat (@pats) {
    say "\nTESTING $pat";
    $_ = "i can match bad crabcatchers from 34 bc and call a cab";
    while (/$pat/g) {
        say "$`<$&>$'";
    }
}

所有五个版本都产生这个输出：

i <c>an match bad crabcatchers from 34 bc and call a cab
i c<a>n match bad crabcatchers from 34 bc and call a cab
i can m<a>tch bad crabcatchers from 34 bc and call a cab
i can mat<c>h bad crabcatchers from 34 bc and call a cab
i can match <b>ad crabcatchers from 34 bc and call a cab
i can match b<a>d crabcatchers from 34 bc and call a cab
i can match bad <c>rabcatchers from 34 bc and call a cab
i can match bad cr<abc>atchers from 34 bc and call a cab
i can match bad crabc<a>tchers from 34 bc and call a cab
i can match bad crabcat<c>hers from 34 bc and call a cab
i can match bad crabcatchers from 34 <bc> and call a cab
i can match bad crabcatchers from 34 bc <a>nd call a cab
i can match bad crabcatchers from 34 bc and <c>all a cab
i can match bad crabcatchers from 34 bc and c<a>ll a cab
i can match bad crabcatchers from 34 bc and call <a> cab
i can match bad crabcatchers from 34 bc and call a <c>ab
i can match bad crabcatchers from 34 bc and call a c<ab>

甜，嗯？

编辑：对于开始部分的x，只需在比赛开始时将任何x 放在a 部分的第一个可选捕获组之前，所以像这样：

x(a)?(b)?(c)?(?(1)|(?(2)|(?(3)|(*FAIL))))

或者像这样

(?x)                        # enable non-insane mode

(?<Whole_Match>
    x                       # first match some leader string

    # now match a, b, and c, in that order, and each optional
    (?<Group_A> a ) ?
    (?<Group_B> b ) ?  
    (?<Group_C> c ) ?

    # now make sure we got at least one of a, b, or c
    (?(<Group_A>)           # SUCCEED!
      | (?(<Group_B>)       # SUCCEED!
          | (?(<Group_C>)   # SUCCEED!
              |             (*FAIL)
            )
        )
    )
)

测试句是在没有x 部分的情况下构建的，所以它不会起作用，但我想我已经表明了我的意思。请注意，所有 x、a、b 和 c 都可以是任意复杂的模式（是的，甚至是递归的），而不仅仅是单个字母，而且它们是否使用编号的捕获组也没关系甚至是他们自己的。

如果你想通过前瞻来解决这个问题，你可以这样做：

(?x)

(?(DEFINE)
       (?<Group_A> a)
       (?<Group_B> b)
       (?<Group_C> c)
)

x

(?= (?&Group_A)
  | (?&Group_B)
  | (?&Group_C)
)

(?&Group_A) ?
(?&Group_B) ?
(?&Group_C) ?

下面是在测试程序中添加到@pats 数组的内容，以表明这种方法也有效：

qr{
    (?(DEFINE)
        (?<Group_A> a)
        (?<Group_B> b)
        (?<Group_C> c)
    )

    (?= (?&Group_A)
      | (?&Group_B)
      | (?&Group_C)
    )

    (?&Group_A) ?
    (?&Group_B) ?
    (?&Group_C) ?
}x

请您注意，即使使用前瞻技术，我仍然设法从不重复任何 a、b 或 c。

我赢了吗？ ☺

Answer 4

如果您不需要找到最大（贪婪）匹配，则可以删除“按该顺序”，因为如果您匹配 x(a|b|c) 并忽略您已经匹配的任何以下文本“至少一个、b 和 c，按此顺序”。换句话说，如果您只需要一个真/假答案（匹配与否），那么x(a|b|c) 就足够了。 （另一个假设：您试图确定输入字符串是否包含匹配，而不是整个字符串是否与正则表达式匹配。即参见@Alan Moore 的问题。）

但是，如果您想确定最大匹配，或者与整个输入字符串匹配，您可以使用前瞻：x(?=(a|b|c))a?b?c?

那里有一些冗余，但比您试图避免的组合方法要少得多。

Answer 5

这是我能想到的最短的：

x(ab?c?|bc?|c)

我相信它符合标准，同时最大限度地减少重复（尽管有一些）。它还避免使用任何前瞻或其他处理器密集型表达式，这可能比节省正则表达式字符串长度更有价值。

此版本重复c 三遍。您可以对其进行调整，使a 或b 成为重复频率最高的一个，因此您可以选择a、b 和c 中最短的一个作为重复3 次的那个。

Answer 6

如果您没有前瞻功能，这并不重要。

x(ab?c?|bc?|c)

Answer 7

怎么样

x(?=[abc])a?b?c?