gawk 和 PROCINFO 无法按预期对较长的字符串进行排序

Question

假设我有一个简单的小字符串文件，我想按行长排序：

$ cat file1
123
2
45
12345
123456789
1

我可以编写一个gawk 脚本，使用函数和PROCINFO["sorted_in"] 对这些字符串进行排序：

$ gawk 'function cmp_len(i1, v1, i2, v2) {
            return length(v1) - length(v2)
      }
      NR==FNR{arr[$0]; next}
      END{PROCINFO["sorted_in"] = "cmp_len"
      for (e in arr) print e
      } 
      ' file1
1
2
45
123
12345
123456789

完美！

但现在假设我在该文件中添加了一些更长的字符串：

$ cat file2
123
2
45
xyxyxyxyxyyxyxyxyxyxyyxyxyxxyxyxyxyyxyxyxyxyyx
12345
56565656565656565665656566565656656565656
123456789
1

它坏了：

$ gawk 'function cmp_len(i1, v1, i2, v2) {
            return length(v1) - length(v2)
      }
      NR==FNR{arr[$0]; next}
      END{PROCINFO["sorted_in"] = "cmp_len"
      for (e in arr) print e
      } 
      ' file2
123456789
56565656565656565665656566565656656565656
1
2
45
123
12345
xyxyxyxyxyyxyxyxyxyxyyxyxyxxyxyxyxyyxyxyxyxyyx

这样可以正常工作：

$ awk '{ print length()"\t"$0}' file2 | sort -n | cut -f2
# expected output by length...

但这让我正在编写的脚本更加困难。

知道为什么PROCINFO 在此示例中不能使用较长的字符串吗？

Answer 1

来自manual：

这里，“i1”和“i2”是索引，“v1”和“v2”是被比较的两个元素的对应值。

您的比较函数是比较数组的值，而不是索引。并且值总是空字符串，所以函数总是返回 0。把它改成

function cmp_len(i1, v1, i2, v2) {
         return length(i1) - length(i2)
}            

你会得到你想要的订单。或者更好的是，缓存长度并使用内置比较，因为存储了有意义的值：

gawk '
NR==FNR { arr[$0] = length($0) }
END {
        PROCINFO["sorted_in"] = "@val_num_asc"
        for (e in arr) print e
} 
' file1