无法在 AWK 中创建阶乘函数

Question

代码

 #!/usr/bin/awk            

 # Sed and AWK by O'Reilly (p.179)

 # Example of what should happen: factorial 5 gives
 #   factorial
 #   Enter number: 3
 #   The factorial of 3 is 6


 BEGIN {
     printf("Enter number: ")
 }

 $1 ~ /^[0-9]+$/ {
     # assign value of $1 to number & fact
     number = $1 
     if (number == 0) 
         fact = 1
     else
         fact = number

     for (x = 1; x < number; x++)
         fact *=x
     printf("The factorial of %d is %g\n", number, fact)

     exit
 }

 # if not a number, prompt again.
 { printf("\nInvalid entry. Enter a number: ")
 }

我运行命令失败

./factorial.awk

我明白了

/usr/bin/awk: syntax error at source line 1
 context is
         >>>  <<< ./factorial.awk
/usr/bin/awk: bailing out at source line 1

错误信息是什么意思？

Answer 1

我认为问题在于您正在编写一个 shell 脚本并将其传递给 awk 执行。以下是一个 shell 脚本，因此是 #! /bin/sh，因此它将被传递给 shell（在这种情况下与 Bourne 兼容）。

#! /bin/sh
awk 'BEGIN { printf("Hello world!\n"); exit }'

she-bang (#!) 行告诉当前解释器将脚本传递给哪个解释器执行。您必须将脚本传递给awk 解释器，因此您需要显式调用awk。这假设 awk 在您的路径中的某处。

然而，下面是一个awk 脚本。

#! /usr/bin/awk -f
BEGIN {
    printf("Hello world!\n");
    exit
}

she-bang 调用 awk 并将脚本作为输入传递。在这种情况下，您不需要显式调用awk，也不需要引用整个脚本，因为它直接传递给awk。

将 she-bang 想象为 获取 she-bang 之后的内容，附加文件名，然后执行它。 Wikipedia 很好地描述了用法，包括一些解决 path to the interpreter 问题的常用方法。

Answer 2

可能是一个愚蠢的答案，但在我的终端中我必须输入：

./factorial.awk

文件是 factorial.awk。

您可以编辑路径环境变量以包含 .但是 ./ 我认为应该可以正常工作。并添加 .在某些情况下，你会运行你没想到的代码，到 $PATH 可能会被证明是非常危险的。

这样行吗？？

编辑：

./factorial.awk -bash: ./factorial.awk: /usr/bin/gawk: 错误的解释器：没有这样的文件或目录

这表示它运行了文件但找不到程序 gawk。 请输入“which gawk”，然后输入“which awk”。

你的第一行应该是：

#!/usr/bin/awk

另外，为了逗我开心，输入：

sudo apt-get install gawk

这将确保您的系统实际上有 gawk。

编辑2： 我看了你的代码，这就是我现在所拥有的。我删除了两个引号和一个破折号。

#!/usr/bin/gawk                                                                                                                                        

# I think we do not need these (p.179) so I comment them out, since I do not know where else to put them.
# The same bug occurs also with them.
#fact = number
#for (x = number -1 ; x > 1; x--)
#    fact *= x

awk # factorial: returns factorial of user-supplied number
    BEGIN {
    printf("Enter number: ")
    }

   $1 ~ /^[0-9]+$/ {
   # assign value of $1 to number & fact
   number = $1 
   if (number == 0) 
       fact = 1
   else
       fact = number
   #loop to multiply fact*x until x = 1
   for (x = number - 1; x > 1; x--)
       fact *= x
   printf("The factorial of %d is %g\n", number, fact)
   #exit -- saves user from typing ^-d
   exit
}

# if not a number, prompt again.
{ printf("\nInvalid entry. Enter a number: ")
}

Answer 3

可能没那么复杂。

#!/usr/bin/awk ---------> #!/usr/bin/awk -f

Answer 4

检查是否有文件/usr/bin/gawk；如果没有，请使用 awk 的路径或 gawk 的正确位置。

另外，您是否使脚本可执行？

另外，你的 PATH 中有当前目录吗？

Answer 5

我通过运行让脚本在 Ubuntu 和 OS X 中运行

awk -f factorial.awk

虽然书上这么说，但您似乎无法按如下方式运行脚本

./factorial.awk 

Answer 6

这是一个递归版本：

#!/usr/bin/awk -f
function f(x) {
    if (x <= 1) return 1
    return (f(x-1) *x)} 

BEGIN {
    printf("Enter number: ")
}

$1 ~ /^[0-9]+$/ {
    printf("The factorial of %d is %d\n", $1, f($1))
    exit
}

{ printf("\nInvalid entry. Enter a number: ")
}

Answer 7

这个问题是谷歌搜索短语“awk factorial”的热门问题，所以这里有一个在 awk 中打印阶乘的简单方法：

$ awk 'BEGIN{x=1;for(i=2;i<=6;i++)x*=i;print x}'
720

作为一个shell函数（-v后面的空格是macOS自带的nawk需要的，gawk不需要）：

$ fac(){ awk -v "n=$1" 'BEGIN{x=1;for(i=2;i<=n;i++)x*=i;print x}';}
$ fac 6
720

作为计算 k 组合的 awk 函数：

$ awk 'function f(x){r=1;for(i=2;i<=x;i++)r*=i;return r}BEGIN{n=5;k=3;print f(n)/(f(k)*f(n-k))}'
10