Perl——未初始化的变量

Question

发生了什么事？我创建了一个简单的程序来读取行并在文件上打印输出。但它会引发一些错误......

这里的代码和它的解释在 cmets 上：

use warnings;
use List::MoreUtils qw(indexes);

my @array_words = ();
my @array_split = ();
my @array_of_zeros = (0);
my $index = 0;

open my $info, 'models/busquedas.csv';
open my $model, '>>models/model.txt';

#First while is to count the words and store it into an array
while( my $line = <$info>)  {
    @array_split = regex($line);
    for (my $i=0; $i < scalar(@array_split); $i++) {
            # Get the index if the word is repeated
        $index = indexes { $_ eq $array_split[$i] } $array_words[$i];
            # if the word is not repeated then save it to the array by 
            # checking the index
        if ($index != -1){ push(@array_words, $array_split[$i]); }
    }
}

print $model @array_words;

sub regex{
    # get only basic info like: 'texto judicial madrid' instead of the full url
    if ($_[0] =~ m/textolibre=/ and 
        $. < 3521239 && 
        $_[0] =~ m/textolibre=(.*?)&translated/) {
        return split(/\+/, $_[0]);
    }
}

而我不明白的错误是：

Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12216.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12216.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12216.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12217.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12217.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12217.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12217.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12217.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12218.
Use of uninitialized value $index in numeric ne (!=) at classifier.pl line 21, <$info> line 12218.

为什么未初始化 $index ？我已经声明它并用 0 值初始化它！ 我该如何解决这个问题？

Answer 1

你已经用零初始化了变量，但是你改变了它的值

$index = indexes { $_ eq $array_split[$i] } $array_words[$i];

该函数可能返回一个 undef（因为 $array_words[$i] 不等于 $array_split[$i]）。否则它会返回一个，因为列表中只有一个元素。

顺便说一句，如果您不需要循环外的值，则在循环外初始化变量是一种不好的做法。您可以在使用indexes 填充它的同一行声明my $index。

Answer 2

正如已经观察到的，indexes 子例程不是这样工作的。它返回一个索引的list，块的计算结果为true。在这样的标量上下文中使用它是错误的。

如果您要为此使用库，则需要 any - 也来自 List::MoreUtils。代码如下所示

while( my $line = <$info>)  {
    @array_split = regex($line);
    for my $word (@array_split) {
      push @array_words, $word unless any { $_ eq $word } @array_words;
    }
}

但是我认为你想要一些更简单的东西。根据我对您的代码的理解，Perl 哈希将满足您的需求。

我已经像这样重构了你的程序。希望对你有帮助。

基本上，如果该行中的每个“单词”尚未在散列中，则将其推送到 @array_words。

您的regex 子例程中似乎也存在错误。声明

return split(/\+/, $_[0]);

分割整行并返回结果。我认为它应该只拆分您刚刚提取的 URL 的查询部分，像这样

return split /\+/, $1;

通常您应该检查open 调用是否成功。添加 autodie 杂注会为您隐式执行此操作。

use strict;
use warnings;
use autodie;

open my $info,  '<',  'models/busquedas.csv';
open my $model, '>>', 'models/model.txt';

my %unique_words;
my @array_words;

#First while is to count the words and store it into an array
while( my $line = <$info>)  {
  for my $word (regex($line)) {
    push @array_words, $word unless $unique_words{$word}++;
  }
}

print $model "$_\n" for @array_words;

sub regex {

  my ($line) = @_;

  # get only basic info like: 'texto judicial madrid' instead of the full url
  return unless $line =~ /textolibre=/ and $. < 3521239;
  if ( $line =~ /textolibre=(.*?)&translated/ ) {
    return split /\+/, $1;
  }
}