在某些部分禁用 DBI HandleError

Question

有没有办法在脚本的某些部分“关闭”Perl 中的 DBI HandleError 属性，就像可以关闭 RaiseError 一样？

例子：

my $dbh = DBI->connect("DBI:SQLite:dbname=file.db","","",{ PrintError => 0, RaiseError => 0, 
                                                           HandleError => sub{ Log("ERROR: Something failed in db"); exit 1 } }) 
        or die "Couldn't connect";
        
for my $table (@db_tables){
  $dbh->do("delete from $table") 
          or do{ Log("ERROR: Delete failed"); next };

  Log("Table [$table] content was deleted");
}
    
exit 0;

在这里，我不希望 HandleError 仅仅因为无法删除其中一个表的内容而终止脚本。我想手动处理错误。

Answer 1

HandleError attribute 可以随时更改。由于您通过进入 $dbh 中的哈希引用直接访问它，因此您可以简单地 localize 它。

for my $table (@db_tables){
    local $dbh->{HandleError}; # it's now undef
    $dbh->do("delete from $table") 
          or do{ Log("ERROR: Delete failed"); next };

    Log("Table [$table] content was deleted");
}

更好的实现是正确处理错误，并且只设置一次本地化。为此，请在循环周围创建一个外部范围。

{
    local $dbh->{HandleError} = sub {
        my (undef, $error) = @_
        Log("ERROR: Delete failed ($error)");
    };

    for my $table (@db_tables){
        $dbh->do("delete from $table") 
            and Log("Table [$table] content was deleted");
    }
}

在这两种情况下，只有在此范围内的代码及其内部的任何范围内运行时，该值才会被覆盖。一旦范围结束，它会自动恢复。