在 Perl 中比较 XML 中的字符串？

Question

完全免责声明：我是 Perl 的新手，一周或更短的经验。在工作中，我目前的项目涉及一个过程，在该过程中，我们从各个机构获取表示课程目录的 XML 文件，并将它们连接到一个文件中。我有一个可以正常工作的 Perl 脚本 + 模块，可以做到这一点；但是，我希望通过检查合并的文件是否满足以下条件来添加一些额外的功能：

1) 每个班级列表都来自同一学期（包含在标签中）

2) 每个班级都来自同一年（这包含在标签中）

这是我当前在合并后运行的子程序（这意味着问题肯定在下面的代码中）：

sub check_files {
    my ($self, $file) = @_;
    my $parser;
    my $parsed;
    my @semesters;
    my @years;
    my $answer = 0;
    my $correct = 0;

    $parser = XML::LibXML->new;
    $parsed = $parser->parse_file($file);

    @semesters = $parsed->getElementsByTagName("SEMESTER");
    @years = $parsed->getElementsByTagName("YEAR");

    foreach my $semester1 (@semesters) {        
        my $semester2 = $semesters[1];

        if($semester1 ne $semester2) {
            if($semester1 ne "<SEMESTER>Do not delete this row</SEMESTER>") {
                print "Check semesters in data! $semester1 $semester2 \n\n";
                $answer += 1;
            }
        } else {
            print "Equal strings: $semester1 $semester2 \n\n";
            $correct += 1;
        }
    }

    foreach my $year1 (@years) {
        my $year2 = $years[1];

        if($year1 ne $year2) {
            if($year1 ne "<YEAR>Do not delete this row</YEAR>") {
                print "Check years in data! $year1 $year2 \n\n";
                $answer += 1;
            }           
        } else {
            print "Equal strings: $year1 $year2 \n\n";
            $correct += 1;
        }
    }

    print "Errors: $answer Correct: $correct \n\n";
    return $answer;

}

我根据元素 1 而不是 0 检查所有内容，因为连接的第一个文件是标题行（应该等于“不要删除此行”的内容）。因此，“不要删除”的东西应该总是元素 0。

我在控制台中收到很多“检查数据中的学期！2013 2013”​​行。事实上，我的 $correct 变量增加的唯一时间是当条件失败时标题行。这让我觉得字符串比较有点搞砸了；我能想到的唯一解释是指针问题和编码。但同样，我上周才开始使用 Perl，所以我真的不知道我在说什么。我知道我的代码也不优雅，对此我深表歉意。

感谢任何可以提供帮助的人，或者甚至阅读本文并决定不提供帮助的人。

Answer 1

当我针对您显示的数据运行您的代码时，我没有得到您描述的输出，但我确实为您提供了解决方案

您确实需要了解 XML 数据。它的嵌套非常像函数式编程语言，所以标签必须是平衡的，并且总是有一个单一的根节点。在你的数据中它被称为<ROOT>，如果你在文件的末尾看一下，就会有一个结束</ROOT>

此代码通过使用 XPath 表达式查找除第一个 SECTION 元素之外的所有元素，然后从每个元素中提取 YEAR 和 SEMESTER 子元素的值，并在几个哈希

如果找到多年或多个学期，我不知道您希望您的子例程做什么，所以这一切只是打印几行摘要行。我希望你能理解如何从这里继续下去

sub check_files2 {
    my $self = shift;
    my ($file) = @_;

    my $doc = XML::LibXML->load_xml(location => $file);

    my @sections = $doc->findnodes('/ROOT/SECTION[position() > 1]');
    printf "%d sections found after the first\n", scalar @sections;

    my (%years, %semesters);

    for my $section ( @sections ) {
        my $year = $section->findvalue('YEAR');
        my $semester = $section->findvalue('SEMESTER');
        ++$semesters{$semester};
        ++$years{$year};
    }

    my @years = keys %years;
    printf "%d different years: %s\n", scalar @years, "@years";

    my @semesters = keys %semesters;
    printf "%d different semesters: %s\n", scalar @semesters, "@semesters";
}

输出

24 sections found after the first
1 different years: 2013
1 different semesters: F