重塑后携带字符串变量的字符串标签

Question

我在 Stata 中有如下所示的数据集

entityID    indicator    indicatordescr    indicatorvalue
1           gdp          Gross Domestic    100
1           pop          Population        15
1           area         Area              50
2           gdp          Gross Domestic    200
2           pop          Population        10
2           area         Area              300

indicator 的值和indicatordescr 的值之间存在一对一的映射关系。

我想把它改成宽的，即：

entityID    gdp     pop     area
1           100     15      50
2           200     10      300

我希望gdp 变量标签为“国内生产总值”、pop 标签“人口”和area“面积”。

不幸的是，据我了解，无法将indicatordescr 的值分配为indicator 的值标签，因此reshape 无法将这些值标签转换为变量标签。

我看过这个：Bring value labels to variable labels when reshaping wide

还有这个：http://www.stata.com/support/faqs/data-management/apply-labels-after-reshape/

但不明白如何将这些应用到我的案例中。

注意：reshape 后的变量标记必须以编程方式完成，因为indicator 和indicatordescr 有很多值。

Answer 1

这里的“字符串标签”是非正式的； Stata 不支持字符串变量的值标签。然而，这里想要的是字符串变量的不同值在重塑时成为变量标签。

存在各种变通方法。这是一个：将信息放入变量名中，然后再次取出。

clear 
input entityID  str4 indicator   str14 indicatordescr    indicatorvalue
1           gdp          "Gross Domestic"    100
1           pop          "Population"        15
1           area         "Area"              50
2           gdp          "Gross Domestic"    200
2           pop          "Population"        10
2           area         "Area"              300
end 

gen what = indicator + "_"  + subinstr(indicatordescr, " ", "_", .)  
keep entityID what indicatorvalue 
reshape wide indicatorvalue , i(entityID) j(what) string 

foreach v of var indicator* {
    local V : subinstr local v "_" " ", all
    local new : word 1 of `V' 
    rename `v' `new'
    local V = substr("`V'", strpos("`V'", " ") + 1, .)
    label var `new' "`V'"
}

renpfix indicatorvalue 

编辑如果变量名的长度很长，请尝试另一种解决方法：

clear 
input entityID  str4 indicator   str14 indicatordescr    indicatorvalue
1           gdp          "Gross Domestic"    100
1           pop          "Population"        15
1           area         "Area"              50
2           gdp          "Gross Domestic"    200
2           pop          "Population"        10
2           area         "Area"              300
end 

mata : sdata = uniqrows(st_sdata(., "indicator indicatordescr")) 
keep entityID indicator indicatorvalue 
reshape wide indicatorvalue , i(entityID) j(indicator) string 
renpfix indicatorvalue 
mata : for(i = 1; i <= rows(sdata); i++) stata("label var " + sdata[i, 1] + "  " + char(34) + sdata[i,2] + char(34))
end 

后期编辑 虽然上述方法被称为变通方法，但它是比以前更好的解决方案。