使用 Perl 捕获输出，直到找到特定模式

Question

我觉得我在这里遗漏了一些非常简单的东西，但这是我第一次需要这样做并且找不到示例。

我有一个巨大的foreach 循环，它遍历输出日志并根据匹配的正则表达式提取各种信息。我的主要问题是一些较大类型的输出有页眉和页脚，比如*** Begin bangle tracking log***，后面跟着几行乱码，然后是***End bangle tracking log***。

有没有办法从foreach 循环中创建一个内部循环来存储所有行，直到找到页脚？

foreach my $line( @parseme )
{
    if( $line =~ m/***Begin bangle tracking log***/ )
    {
        #Help! Push all lines into an array until bangle tracking footer is found.
    }
    if( $line =~ m/Other stuff I am tracking/ )
    {
        #Do other things
    }
}

Answer 1

您可以使用range operator，它在标量上下文中充当触发器：

foreach ( @parseme ) {
    if ( /Begin bangle tracking log/ .. /End bangle tracking log/ ) {
        push @array, $_;
    }
    # other stuff...
}

我将$_ 用于foreach 循环，因为它允许更简洁的语法。如果你愿意，你可以使用另一个变量，但是你必须把条件写成这样：

if ( $line =~ /Begin .../ .. $line =~ /End .../ ) {

加上一些额外的括号可能更易读：

if ( ($line =~ /Begin .../) .. ($line =~ /End .../) ) {

关于触发器运算符的一个需要注意的问题是，即使在循环结束后它也会记住它的状态。这意味着，如果您打算再次运行循环，您真的应该确保@parseme 数组以匹配/End .../ 正则表达式的行结束，以便触发器下次循环开始时将处于已知状态。

编辑：根据下面 DVK 的评论，如果您想在到达页脚行后立即处理收集的行，您可以通过检查 .. 运算符的返回值来实现，最后一行以E0 结尾：

foreach ( @parseme ) {
    my $in_block = /Begin bangle tracking log/ .. /End bangle tracking log/;
    if ( $in_block ) {
        push @array, $_;
    }
    if ( $in_block =~ /E0$/ ) {  # last line
        # process the lines in @array
        @array = ();
    }
    # other stuff...
}

Answer 2

您可以通过实现一个原始状态机轻松地做到这一点：

my $inside_bangle = 0; # 0=outside block, 1=inside
my @buffer;
foreach my $line( @parseme ) {
    if  ($line =~ m/***Begin bangle tracking log***/ ) {
        $inside_bangle = 1;
        next;
    }
    if ($line =~ m/***End bangle tracking log***/ ) {
        $inside_bangle = 0;
        # PROCESS @buffer somehow
        next;
    }
    if ($inside_bangle) {
        push @buffer, $line;
        next;
    }
    if ($line =~ m/other stuff i am tracking/ ) {
        #Do other things
    }
}

另一种选择是使用触发器 (..)

Answer 3

您可能正在寻找.. 运算符，它在与正则表达式一起应用时具有一些神奇的属性。下面的例子是从PLEAC偷来的：

while (<>) {
    if (/BEGIN PATTERN/ .. /END PATTERN/) {
        # line falls between BEGIN and END in the
        # text, inclusive.
    }
}

在块中，按照您认为合适的方式附加到您的数组变量。

Answer 4

现在你可以存储你的日志 sn-p 的多个实例，如果它出现不止一次（DVK 的原始代码）：

my $inside_bangle = 0; # 0=outside block, 1=inside
my %buffer;
my $index = 0;
foreach my $line( @parseme ) {
    if  ($line =~ m/***Begin bangle tracking log***/ ) {
        $inside_bangle = 1;
        next;
    }
    if ($line =~ m/***End bangle tracking log***/ ) {
        $inside_bangle = 0;
        $index++;
        # PROCESS @buffer somehow
        next;
    }
    if ($inside_bangle) {
        push @{ $buffer{$index} }, $line;
        next;
    }
    if ($line =~ m/other stuff i am tracking/ ) {
        #Do other things
    }
}

这是我最初写的，但我认为 DVK 的代码更具可读性和简洁性：

open FILE, "<", 'testfile.log';
@parseme = <FILE>;
my $initialize = shift @parseme;
my $startLogging = $initialize =~ m/^Log Start$/ ? 1 : 0; # test if first line of array is start of log
my %storage = ();
my $index = 0;
foreach my $line (@parseme) {
 $startLogging = 1 if $line =~ m/^Log Start$/;
 if ($startLogging == 1) {
  push( @{ $storage{$index} }, $line ) unless $line =~ m/(Log Start|Log End)$/;
  if ($line =~ m/^Log End$/) {
   $startLogging = 0;
   $index++;
  }
 }
}